906221_fr-FR

liliconcom

Variables de valeur de terme dynamiques mémorisées par les paramètres du profileur bivarié

Salut tout le monde,

J'apprécierais vraiment un peu d'aide avec certains scripts.

Je travaille sur un script d'ajustement bivarié qui prend deux colonnes d'une boîte de dialogue. Je souhaite charger un profileur dont certains paramètres sont déjà mémorisés. Le problème est que je ne trouve pas la bonne façon de référencer/substituer le nom de la colonne dans la valeur du terme du profileur. Dans l'exemple de code ci-dessous, j'ai conservé les références codées en dur à la colonne et le script fonctionne, mais j'ai besoin qu'il soit flexible avec différents noms de colonnes. J'ai rencontré un utilisateur qui a rencontré un problème similaire, mais je n'ai pas réussi à adapter la solution qui lui a fonctionné à mon exemple (voir Profileur : L'utilisation de variables dans un script de valeur de terme ne fonctionne pas) . Mon expérience jusqu'à présent en matière d'écriture d'expressions et de substitution de termes s'est limitée aux colonnes de formules, ce problème est donc un peu trop complexe pour moi.

Toute aide pour corriger ce problème serait grandement appréciée.

Cordialement,

Cathal

New Table( "Example",
	Add Rows( 10 ),
	New Column( "X",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [20, 40, 60, 80, 100, 120, 140, 160, 180, 200] )
	),
	New Column( "Y",
		Numeric,
		"Continuous",
		Format( "Best", 15 ),
		Set Values( [1, 2, 3, 4, 5, 6, 7, 8, 9, 10] )
	)
); 

// Open dialog to select columns
dlg = Column Dialog(
    colX = Col List( "X",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
    colY = Col List( "Y",
        Min Col( 1 ), 
        Max Col( 1 ),
    ),
);

// Store list of selected columns
Eval List( Remove( dlg, -1 ) );

// Launch platform: Bivariate
report = Bivariate( 
	Y( colY[1] ) , 
	X( colX[1] ), 
		Fit Polynomial(	1,
		{Profiler(
			1,
			Confidence Intervals( 1 ),	
			Term Value( "X"n( 30, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "1-Month", Differences Report( 0 ) ),
			Term Value( "X"n( 60, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "2-Months" ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ), // Need to replace with dynamic reference
			Remember Settings( "3-Months", Differences Report( 1 ) ),
			Term Value( "X"n( 90, Lock( 0 ), Show( 1 ) ) ) // Need to replace with dynamic reference
		)}
	)
);

Automatisation et scriptsObjet : Variables de valeur de terme dynamiques mémorisées par les paramètres du profileur bivarié

Je pense que quelque chose comme ça pourrait fonctionner

Names Default To Here(1);

dt = New Table("Example",
	Add Rows(10),
	New Column("X",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([20, 40, 60, 80, 100, 120, 140, 160, 180, 200])
	),
	New Column("Y",
		Numeric,
		"Continuous",
		Format("Best", 15),
		Set Values([1, 2, 3, 4, 5, 6, 7, 8, 9, 10])
	)
); 

dlg = Column Dialog(
	colX = Col List("X", Min Col(1), Max Col(1), ),
	colY = Col List("Y", Min Col(1), Max Col(1), ),

);
Eval List(Remove(dlg, -1));

report = Eval(Substitute(
	Expr(dt << Bivariate(
		Y(colY[1]),
		X(colX[1]),
		Fit Polynomial(
			1,
			{Profiler(
				1,
				Confidence Intervals(1),
				Term Value(_x_(30, Lock(0), Show(1))),
				Remember Settings("1-Month", Differences Report(0)),
				Term Value(_x_(60, Lock(0), Show(1))),
				Remember Settings("2-Months"),
				Term Value(_x_(90, Lock(0), Show(1))),
				Remember Settings("3-Months", Differences Report(1)),
				Term Value(_x_(90, Lock(0), Show(1)))
			)}
		)
	)),
	Expr(_x_), Name Expr(AsColumn(dt, colX[1]));
));

Objet : Variables de valeur de terme dynamiques mémorisées par les paramètres du profileur bivarié

Ça marche parfaitement. Merci Jarmo !