905914_ko-KR

liliconcom

ComboBox 풀다운 메뉴를 사용하여 Graph Builder에서 위도와 경도를 동적으로 변경합니다.

참고: 아래에 데이터와 스크립트가 업로드되었습니다...

다음 스크립트를 개발했습니다. 이 스크립트는 먼저 이동 경로를 보여주는 넓은 영역을 표시합니다. 사용자가 특정 위치의 코드(이 예에서는 1 또는 2)를 입력할 수 있는 모달 창이 나타납니다. 이 정보를 사용하면 그래프가 해당 위치로 확대됩니다. 이 모든 기능은 잘 작동하지만 제가 원하는 기능은 아닙니다. 가장 중요한 것은, 선택이 완료되고 스크립트가 종료되면 대화 상자가 사라진다는 것입니다. 두 번째로, 이 기능을 콤보 상자 풀다운 메뉴와 함께 사용하려고 했습니다. 메뉴 자체는 작동하는데, 어떤 이유에서인지 그래프에서 변경 사항을 적용할 수 있는 옵션이 나타나지 않습니다.

모달 텍스트 상자에 대한 내용은 다음과 같습니다.

Names Default To Here( 1 );

dt = Data Table( "Test Data" );

gb = Graph Builder(
	Graph Spacing( 10 ),
	Spacing Borders( 1 ),
	Variables( X( :Longitude ), Y( :Latitude ) ),
	Elements( Points( X, Y, Legend( 3 ) ) ),
	SendToReport(
		Dispatch( {}, "Longitude", ScaleBox, {Min( -104 ), Max( -98.47 )} ),
		Dispatch( {}, "Latitude", ScaleBox, {Min( 29.21 ), Max( 33.30 )} ),		
		Dispatch( {}, "Graph Builder", FrameBox,
			{Background Map( Images( "Street Map Service", "Mapbox Satellite", "" ) )}
		)
	)
);

// Build the modal input window
New Window( "Pick a spot", 
	Modal,
	H List Box(
		V List Box( Text Box( "Location Number:" ), ),
		V List Box( box = Number Edit Box( "Enter location number..." ), )
	),
	Button Box( "OK", 
		// Script to run when "OK" is clicked
		locNum = box << Get;
		Print( "Location Number: " || Char( locNum ) );
	),
	Button Box( "Cancel", 
		// Script to run when "Cancel" is clicked
		Throw()
	)
);


If(
	locNum == 1,
		minLat = 30.99;
		maxLat = 31.06;
		minLong = -101.21;
		maxLong = -101.11;
		run = "1|1";,
	locNum == 2,
		minLat = 31.34;
		maxLat = 31.41;
		minLong = -101.81;
		maxLong = -101.71;
		run = "2|1";
);

gb << Dispatch( {}, "Longitude", ScaleBox, {Min( minLong ), Max( maxLong )} );

gb << Dispatch( {}, "Latitude", ScaleBox, {Min( minLat ), Max( maxLat )} );

초기 지도는 다음과 같습니다...

확대해서 보면 이런 모습입니다...

그래서 제가 고민하는 것은 1) ComboBox를 이것과 함께 작동하게 하려면 어떻게 해야 할까, 2) 스크립트가 완료되지 않도록 해서 사용자가 풀다운 메뉴에서 다른 항목을 계속 선택할 수 있게 하려면 어떻게 해야 할까입니다.

저는 이것이 Set Function 명령과 관련이 있다고 생각하지만, 이것을 작동시키려고 여러 번 시도했지만 아무 소용이 없었습니다.

이에 대한 어떤 지침이라도 감사히 받겠습니다.

감사해요.

자동화 및 스크립팅Re: ComboBox 풀다운 메뉴를 사용하여 Graph Builder에서 위도와 경도를 동적으로 변경

나는 이런 것에 모달 창을 사용하지 않을 것입니다.

Names Default To Here(1);

dt = Data Table("Test Data");

gb = dt << Graph Builder(
	Graph Spacing(10),
	Spacing Borders(1),
	Variables(X(:Longitude), Y(:Latitude)),
	Elements(Points(X, Y, Legend(3))),
	SendToReport(
		Dispatch({}, "Longitude", ScaleBox, {Min(-104), Max(-98.47)}),
		Dispatch({}, "Latitude", ScaleBox, {Min(29.21), Max(33.30)}),
		Dispatch({}, "Graph Builder", FrameBox,
			{Background Map(Images("Street Map Service", "Mapbox Satellite", ""))}
		)
	)
);
wait(0);

cb_expr = Expr(
	locNum = cb_option << get;
	show(locNum);
	If(
		locNum == 1,
			minLat = 30.99;
			maxLat = 31.06;
			minLong = -101.21;
			maxLong = -101.11;
			run = "1|1";,
		locNum == 2,
			minLat = 31.34;
			maxLat = 31.41;
			minLong = -101.81;
			maxLong = -101.71;
			run = "2|1";
	);

	gb << Dispatch({}, "Longitude", ScaleBox, {Min(minLong), Max(maxLong)});

	gb << Dispatch({}, "Latitude", ScaleBox, {Min(minLat), Max(maxLat)});
);


// Build the modal input window
nw = New Window("Pick a spot",
	Lineup Box(N Col(2), 
		Text Box("Location Number:"), 
		cb_option = Combo Box({"1", "2"},
			cb_expr
		),
	),
	Button Box("OK",
		cb_expr; // not necessary if you wish to run when combo box is changed
		Print("Location Number: " || Char(locNum));
	),
	Button Box("Cancel", 
		// Script to run when "Cancel" is clicked
		Throw()
	)
);

나중에 더 많은 옵션을 쉽게 추가할 수 있도록 옵션을 연관 배열로 이동할 수도 있습니다.

Re: ComboBox 풀다운 메뉴를 사용하여 Graph Builder에서 위도와 경도를 동적으로 변경

고맙습니다, @jthi . 완벽하네요.

따라서 ComboBox 액션을 Eval() 블록으로 감싸고 ComboBox가 실행될 때 해당 블록을 스크립트로 실행하는 것이 아이디어입니다. 제 생각에는 제가 올바르게 해석한 것 같습니다.

Re: ComboBox 풀다운 메뉴를 사용하여 Graph Builder에서 위도와 경도를 동적으로 변경

콤보 상자 내부에서 표현식을 이동할 수 있지만, 특히 여러 위치에서 동일한 작업을 사용하는 경우 표현식을 분리하면 일반적으로 수정하기가 훨씬 쉽습니다.

더 보기...

Names Default To Here(1);

dt = Data Table("Test Data");

gb = dt << Graph Builder(
	Graph Spacing(10),
	Spacing Borders(1),
	Variables(X(:Longitude), Y(:Latitude)),
	Elements(Points(X, Y, Legend(3))),
	SendToReport(
		Dispatch({}, "Longitude", ScaleBox, {Min(-104), Max(-98.47)}),
		Dispatch({}, "Latitude", ScaleBox, {Min(29.21), Max(33.30)}),
		Dispatch({}, "Graph Builder", FrameBox,
			{Background Map(Images("Street Map Service", "Mapbox Satellite", ""))}
		)
	)
);
wait(0);

// Build the modal input window
nw = New Window("Pick a spot",
	Lineup Box(N Col(2), 
		Text Box("Location Number:"), 
		cb_option = Combo Box({"1", "2"},
			locNum = cb_option << get;
			show(locNum);
			If(
				locNum == 1,
					minLat = 30.99;
					maxLat = 31.06;
					minLong = -101.21;
					maxLong = -101.11;
					run = "1|1";,
				locNum == 2,
					minLat = 31.34;
					maxLat = 31.41;
					minLong = -101.81;
					maxLong = -101.71;
					run = "2|1";
			);

			gb << Dispatch({}, "Longitude", ScaleBox, {Min(minLong), Max(maxLong)});

			gb << Dispatch({}, "Latitude", ScaleBox, {Min(minLat), Max(maxLat)});
		),
	),
	Button Box("OK",
		locNum = cb_option << get;
		show(locNum);
		If(
			locNum == 1,
				minLat = 30.99;
				maxLat = 31.06;
				minLong = -101.21;
				maxLong = -101.11;
				run = "1|1";,
			locNum == 2,
				minLat = 31.34;
				maxLat = 31.41;
				minLong = -101.81;
				maxLong = -101.71;
				run = "2|1";
		);

		gb << Dispatch({}, "Longitude", ScaleBox, {Min(minLong), Max(maxLong)});

		gb << Dispatch({}, "Latitude", ScaleBox, {Min(minLat), Max(maxLat)});
		Print("Location Number: " || Char(locNum));
	),
	Button Box("Cancel", 
		// Script to run when "Cancel" is clicked
		Throw()
	)
);

<< 대신 << Set Function을 사용할 수도 있습니다. 사용할 수 있는 인수, 콤보 상자 )

Names Default To Here(1);

aa_options = Associative Array(); 
aa_options[1] = [
	"minLat" => 30.99,
	"maxLat" => 31.06,
	"minLong" => -101.21,
	"maxLong" => -101.11,
	"run" => "1|1"
];
aa_options[2] = [
	"minLat" => 31.34,
	"maxLat" => 31.41,
	"minLong" => -101.81,
	"maxLong" => -101.71,
	"run" => "2|1"
];

update_graph = Function({cb_ref, idx}, {Default Local},
	s = aa_options[idx];
	show(s);
	gb << Dispatch({}, "Longitude", ScaleBox, {Min(s["minLong"]), Max(s["maxLong"])});
	gb << Dispatch({}, "Latitude", ScaleBox, {Min(s["minLat"]), Max(s["maxLat"])});	
);



dt = Data Table("Test Data");

gb = dt << Graph Builder(
	Graph Spacing(10),
	Spacing Borders(1),
	Variables(X(:Longitude), Y(:Latitude)),
	Elements(Points(X, Y, Legend(3))),
	SendToReport(
		Dispatch({}, "Longitude", ScaleBox, {Min(-104), Max(-98.47)}),
		Dispatch({}, "Latitude", ScaleBox, {Min(29.21), Max(33.30)}),
		Dispatch({}, "Graph Builder", FrameBox,
			{Background Map(Images("Street Map Service", "Mapbox Satellite", ""))}
		)
	)
);
wait(0);


options = Transform Each({item}, aa_options << get keys, Char(item)); // combo box requires strings
nw = New Window("Pick a spot",
	Lineup Box(N Col(2), 
		Text Box("Location Number:"), 
		cb_option = Combo Box(options, 
			<< Set Function(Function({this, idx},
				update_graph(this, idx);
			))
		)
	),
	Button Box("Cancel", 
		<< Set Function(function({this},
			this << close window;
		))
	)
);