update a combo box in which the list comes from a data table that has to be opened by the user

marc_isal-corte

Background

I am creating a small application with tabs, in one of them I request the user to open a data table

In another tab I have a  combo box that displays a list of unique values (“unique_copy_list’) of a column of that data table

cbx1=try(Combo Box(unique_copy_list),),

Problem:

When application is launched not data table is selected thus the  “unique_copy_list” is not available,

There is a way to refresh there the combo box?

Or it's better to use different approach

pmroz

You need to set up a callback to load the combobox.  Here's a little example.  You have to open the Bands Data example dataset for this to work.  I've also included a function to get the unique values for a column.

/* Function Name Get Unique Values

Description: Get the unique values for a column. For example:

    Indications

    ------------

    AAAAA

    BBBBB

    AAAAA

    CCCCC

    CCCCC

unique_list = get unique values (:Indications)

will return {"AAAAA", "BBBBB", "CCCCC"}

Arguments:

dtcol        column descriptor to calculate unique values for

*/

Get Unique Values = Function( {dtcol},{default local},

// Eval/expr trickery to get this to work.

    eval(eval expr(

        Summarize(unique_list = By(expr(dtcol)))));

    unique_list;

);

nw = new window("Test",

    tab box(

        "First tab",

        open_button = button box("Open",

            dt = open();

// This example will work with Bands Data...

            unique_copy_list = get unique values(column(dt, "customer"));

            cbx1 << set items(unique_copy_list);

        ),

       

        "Second tab",

        cbx1 = Combo Box(),        // Initially this will be empty

    )

);