Siempre ha podido subíndices de columnas en una tabla de datos como vectores unidimensionales.En JMP 13 puede suscribir una tabla de datos como una matriz bidimensional.Aquí hay algunos ejemplos usando clase grande.(El último ejemplo muestra el subíndice de la columna).
dt = Open("$SAMPLE_DATA\Big class.jmp");
// fetch a scalar; neither subscript is a matrix
dt[ 4, "height"]; // 66
// fetch a matrix if either is a matrix, even if 1x1
dt[ [4], "height"]; // [66]
dt[ 4, {height}]; // [66]
// fetch a list if character columns are involved.
// notice the matrix is reversing the order
dt[ 4::2, "name"]; // {"JACLYN", "JANE", "LOUISE"}
// fetch an entire dimension using 0 for a subscript
dt[ 1,0 ]; // {"KATIE", 12, "F", 59, 95}
// fetch by column names
dt[[1,3,5],{height,weight}]; // [59 95, 55 74, 52 64]
// fetch by column numbers in matrix or list
dt[[1,3,5],[2 4 5]]; // [12 59 95, 12 55 74, 12 52 64]
dt[[1,3,5],{2,4,5}]; // [12 59 95, 12 55 74, 12 52 64]
// assignments work too. first, fetch a copy
copydt = dt[0,0]; // make a list of the table's data
// Clear the table
dt[0,0] = .; // all rows and cols are missing
// restore the table
dt[0,0] = copydt;
// reverse two columns, top to bottom and left to right
// (do it again to repair the table!)
dt[1::nrows(dt),{name,sex}] = dt[nrows(dt)::1,{sex,name}];
// set from a matrix
dt[2::3,{age,height,weight}] = [22 70 190, 23 73 200 ];
// column subscripting still works...
dt:name[4::7]; // {"JACLYN", "LILLIE", "TIM", "JAMES"}
El subíndice de la tabla de datos hace que sea más fácil trabajar con una tabla que antes; puede intercambiar filas o columnas con una declaración única (ligeramente complicada), o copiar bloques de una tabla a otra, o extraer una matriz de un subconjunto de la tabla utilizando una matriz de filas y una lista de columnas que identifican el subconjunto.
¡Guau!Otra mejora inesperada de JSL.¡Esto es increíble!
Esto puede ser incluso mejor que la mejora de la velocidad de las listas.
Craige@JMP
¡Fantástico!, Esto abre muchas posibilidades para la "programación de tablas de datos", o más bien la programación basada en matrices.
