Sei sempre stato in grado di indicizzare le colonne in una tabella di dati come vettori unidimensionali.In JMP 13 è possibile sottoscrivere una tabella di dati come un array bidimensionale.Ecco alcuni esempi che utilizzano una grande classe.(L'ultimo esempio mostra l'indice di colonna.)
dt = Open("$SAMPLE_DATA\Big class.jmp");
// fetch a scalar; neither subscript is a matrix
dt[ 4, "height"]; // 66
// fetch a matrix if either is a matrix, even if 1x1
dt[ [4], "height"]; // [66]
dt[ 4, {height}]; // [66]
// fetch a list if character columns are involved.
// notice the matrix is reversing the order
dt[ 4::2, "name"]; // {"JACLYN", "JANE", "LOUISE"}
// fetch an entire dimension using 0 for a subscript
dt[ 1,0 ]; // {"KATIE", 12, "F", 59, 95}
// fetch by column names
dt[[1,3,5],{height,weight}]; // [59 95, 55 74, 52 64]
// fetch by column numbers in matrix or list
dt[[1,3,5],[2 4 5]]; // [12 59 95, 12 55 74, 12 52 64]
dt[[1,3,5],{2,4,5}]; // [12 59 95, 12 55 74, 12 52 64]
// assignments work too. first, fetch a copy
copydt = dt[0,0]; // make a list of the table's data
// Clear the table
dt[0,0] = .; // all rows and cols are missing
// restore the table
dt[0,0] = copydt;
// reverse two columns, top to bottom and left to right
// (do it again to repair the table!)
dt[1::nrows(dt),{name,sex}] = dt[nrows(dt)::1,{sex,name}];
// set from a matrix
dt[2::3,{age,height,weight}] = [22 70 190, 23 73 200 ];
// column subscripting still works...
dt:name[4::7]; // {"JACLYN", "LILLIE", "TIM", "JAMES"}
Il subscripting della tabella dati rende più facile lavorare con una tabella rispetto a prima; puoi scambiare righe o colonne con una singola istruzione (leggermente complicata), o copiare blocchi da una tabella all'altra, o estrarre una matrice da un sottoinsieme della tabella utilizzando una matrice di righe e un elenco di colonne che identificano il sottoinsieme.
Oh!Un altro miglioramento JSL inaspettato.Questo è incredibile!
Questo potrebbe essere persino migliore del miglioramento della velocità degli elenchi.
Craige@JMP
Fantastico!, Ciò apre molte possibilità per la "programmazione di tabelle dati", o meglio la programmazione basata su matrici.
