Vous avez toujours été en mesure d'indicer des colonnes dans une table de données sous forme de vecteurs unidimensionnels.Dans JMP 13, vous pouvez inscrire une table de données sous la forme d'un tableau à deux dimensions.Voici quelques exemples utilisant la grande classe.(Le tout dernier exemple montre l'indice de colonne.)
dt = Open("$SAMPLE_DATA\Big class.jmp");
// fetch a scalar; neither subscript is a matrix
dt[ 4, "height"]; // 66
// fetch a matrix if either is a matrix, even if 1x1
dt[ [4], "height"]; // [66]
dt[ 4, {height}]; // [66]
// fetch a list if character columns are involved.
// notice the matrix is reversing the order
dt[ 4::2, "name"]; // {"JACLYN", "JANE", "LOUISE"}
// fetch an entire dimension using 0 for a subscript
dt[ 1,0 ]; // {"KATIE", 12, "F", 59, 95}
// fetch by column names
dt[[1,3,5],{height,weight}]; // [59 95, 55 74, 52 64]
// fetch by column numbers in matrix or list
dt[[1,3,5],[2 4 5]]; // [12 59 95, 12 55 74, 12 52 64]
dt[[1,3,5],{2,4,5}]; // [12 59 95, 12 55 74, 12 52 64]
// assignments work too. first, fetch a copy
copydt = dt[0,0]; // make a list of the table's data
// Clear the table
dt[0,0] = .; // all rows and cols are missing
// restore the table
dt[0,0] = copydt;
// reverse two columns, top to bottom and left to right
// (do it again to repair the table!)
dt[1::nrows(dt),{name,sex}] = dt[nrows(dt)::1,{sex,name}];
// set from a matrix
dt[2::3,{age,height,weight}] = [22 70 190, 23 73 200 ];
// column subscripting still works...
dt:name[4::7]; // {"JACLYN", "LILLIE", "TIM", "JAMES"}
L'indice de table de données facilite le travail avec une table qu'auparavant ; vous pouvez échanger des lignes ou des colonnes avec une seule instruction (légèrement compliquée), ou copier des blocs d'une table à une autre, ou extraire une matrice d'un sous-ensemble de la table en utilisant une matrice de lignes et une liste de colonnes qui identifient le sous-ensemble.
Ouah!Une autre amélioration inattendue de JSL.C'est incroyable!
Cela peut être encore mieux que l'amélioration de la vitesse des listes.
Craige@JMP
Fantastique!, Cela ouvre de nombreuses possibilités de "programmation de table de données", ou plutôt de programmation matricielle.
