Sie konnten Spalten in einer Datentabelle immer als eindimensionale Vektoren tiefstellen.In JMP 13 können Sie eine Datentabelle als zweidimensionales Array indizieren.Hier sind einige Beispiele für die Verwendung großer Klassen.(Das allerletzte Beispiel zeigt die Subskription der Spalte.)
dt = Open("$SAMPLE_DATA\Big class.jmp");
// fetch a scalar; neither subscript is a matrix
dt[ 4, "height"]; // 66
// fetch a matrix if either is a matrix, even if 1x1
dt[ [4], "height"]; // [66]
dt[ 4, {height}]; // [66]
// fetch a list if character columns are involved.
// notice the matrix is reversing the order
dt[ 4::2, "name"]; // {"JACLYN", "JANE", "LOUISE"}
// fetch an entire dimension using 0 for a subscript
dt[ 1,0 ]; // {"KATIE", 12, "F", 59, 95}
// fetch by column names
dt[[1,3,5],{height,weight}]; // [59 95, 55 74, 52 64]
// fetch by column numbers in matrix or list
dt[[1,3,5],[2 4 5]]; // [12 59 95, 12 55 74, 12 52 64]
dt[[1,3,5],{2,4,5}]; // [12 59 95, 12 55 74, 12 52 64]
// assignments work too. first, fetch a copy
copydt = dt[0,0]; // make a list of the table's data
// Clear the table
dt[0,0] = .; // all rows and cols are missing
// restore the table
dt[0,0] = copydt;
// reverse two columns, top to bottom and left to right
// (do it again to repair the table!)
dt[1::nrows(dt),{name,sex}] = dt[nrows(dt)::1,{sex,name}];
// set from a matrix
dt[2::3,{age,height,weight}] = [22 70 190, 23 73 200 ];
// column subscripting still works...
dt:name[4::7]; // {"JACLYN", "LILLIE", "TIM", "JAMES"}
Die Datentabellensubskription macht die Arbeit mit einer Tabelle einfacher als zuvor; Sie können Zeilen oder Spalten mit einer einzigen (etwas komplizierten) Anweisung austauschen, Blöcke von einer Tabelle in eine andere kopieren oder eine Matrix aus einer Teilmenge der Tabelle extrahieren, indem Sie eine Matrix aus Zeilen und eine Liste von Spalten verwenden, die die Teilmenge identifizieren.
Wow!Eine weitere unerwartete JSL-Verbesserung.Das ist unglaublich!
Dies ist möglicherweise sogar besser als die Geschwindigkeitsverbesserung bei Listen.
Craige@JMP
Fantastisch!, Dies eröffnet viele Möglichkeiten für die „Datentabellenprogrammierung“, genauer gesagt für die Matrix-basierte Programmierung.
