899648_zh-CN

liliconcom

制表页列项由 for 循环指定

大家好，

我正在尝试根据 for 循环中的特定列值来制表多种情况。

categorizes = Column(dt, "Categorize");
columnValues = Associative Array(categorizes << Get Values) << Get Keys;
For(i = 1, i <= N Items(columnValues), i++,
	currentItem = columnValues[i];
 
 
	obLoopY = Outline Box("categorize" || Char(currentItem),
		dt << Tabulate(
			Page Column(:Categorize(Char(currentItem))),
			Show Control Panel(0),
			Add Table(
				Column Table(
					Grouping Columns(:Underlayer, :RefEntity),
					Analysis Columns(:M3S_Y)
				),
				Row Table(Grouping Columns(:TargetEntity))
			),
			SendToReport(Dispatch({}, "", TextBox, {Set Base Font("Heading")}))
		)
	);
 
	boxY << append(obLoopY);
);

问题是，currentItem 包含来自 Categorize 列的 columnValues。

如果我仅指定项目值，则假设“a”是columnValues之一。

我将页面列(:Categorize(“a”))添加到 Tabulate 方法中，然后它就可以工作了。

但是我需要从 for 循环运行所有值，我尝试将其设为Page Column(:Categorize(currentItem))，但它不起作用，只是一次给我整个值而不是按 currentItem 拆分。

我试过Page Column( :Categorize( currentItem ) ) 和 Page Column( :Categorize( char(currentItem) ) )，但都没用。或许有更简单的解决方案，但我没找到。

有人可以帮忙吗？

提前致谢

编辑（jthi）：添加了 jsl 格式

自动化和脚本回复：制表循环中指定的页面列项

您可能需要评估这些值，下面是使用 JMP 示例表的示例

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
Summarize(dt, groups = By(:sex));

New Window("test", 
	collector = H List Box()
);

For Each({group}, groups,
	ob = Outline Box("Categorize " || group,
		tab = dt << Tabulate(
			Show Control Panel(0),
			Add Table(
				Column Table(Analysis Columns(:height, :weight), Statistics(Mean)),
				Row Table(Grouping Columns(:age))
			)
		);
		Eval(EvalExpr(
			tab << page column(:sex(Expr(group)));
		));
	);
	collector << Append(ob);
);

如果布局没问题，By 可能也是一个选择

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

tab = dt << Tabulate(
	Show Control Panel(0),
	Add Table(
		Column Table(Analysis Columns(:height, :weight), Statistics(Mean)),
		Row Table(Grouping Columns(:age))
	),
	By(:sex),
	Group Options(Layout("Horizontal List"))
);

回复：制表循环中指定的页面列项

感谢使用 By 也消除了不必要的 for 循环！