899608_es-ES

liliconcom

Aumentar el tamaño de los puntos de datos en el mapa de obleas

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			pcolor = color_list[1];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, filled_rect);
		);,
		Title(" Lot: " || sdt:lot_id[p] || " Route: " || sdt:route[p])
	), 
);

El código JSL anterior es el siguiente: quiero aumentar el tamaño de los puntos dentro del círculo y resaltarlos si tienen una imagen adjunta en un color diferente. ¿Podrían ayudarme con esto?

Editar (jthi): se agregó formato JSL

Automatización y scriptingRe: Aumentar el tamaño de los puntos de datos en el mapa de obleas

¿Qué problemas tienes? ¿Recibes errores? ¿Tamaños de qué puntos? Parece que solo tienes rectángulos dentro del gráfico y su tamaño está determinado por la tabla de datos.

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("left", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("right", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("bottom", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 40000])),
	New Column("top", Numeric, "Continuous", Format("Best", 12), Set Values([30000, 50000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, 1);
		);,
		Title("title")
	), 
);

Re: Aumentar el tamaño de los puntos de datos en el mapa de obleasMuchas gracias por la aclaración. Sí, creé el rectángulo porque no puedo aumentar el tamaño de los puntos de datos dentro del círculo. Si pudieras mostrarme cómo trazar los puntos de datos dentro de un círculo de mapa de obleas y resaltarlos según criterios con diferentes colores o leyendas, sería de gran ayuda. Gracias.Re: Aumentar el tamaño de los puntos de datos en el mapa de obleas

Si desea utilizar marcadores, algo como esto es una opción.

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("x", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("y", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				mstate = Color State("Red");
			,
				mstate = Color State("Black");
			);
			xx = Matrix(:x);
			yy = Matrix(:y);
			Marker(mstate, xx, yy);
		);
	)
);

Pero también puedes usar círculos que podrían dar más flexibilidad.

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				Fill Color("Red");
				Pen Color("Blue");
			,
				Fill Color("Black");
				Pen Color("Black");
			);
			Circle(Eval List({:x, :y}), 10000, "FILL")
		);
	)
);

Y una opción más podría ser hacer la mayor parte de esto en el generador de gráficos, dependiendo de lo que estés tratando de lograr.

Re: Aumentar el tamaño de los puntos de datos en el mapa de obleas

Un millón de gracias Jthi Funcionó perfectamente como quería.