899608_zh-CN

liliconcom

增加晶圆图中数据点的大小

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			pcolor = color_list[1];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, filled_rect);
		);,
		Title(" Lot: " || sdt:lot_id[p] || " Route: " || sdt:route[p])
	), 
);

以上是我的 JSL 代码，我想增加圆内点的大小，并且如果这些点上附加了不同颜色的图像，则需要突出显示这些点。请问您能帮我解决这个问题吗？

编辑（jthi）：添加 JSL 格式

自动化和脚本回复：增加晶圆图中数据点的大小

你遇到了什么问题？有错误吗？哪些点的大小？你的图表里好像只有矩形，而且它们的大小是由数据表决定的？

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("left", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("right", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("bottom", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 40000])),
	New Column("top", Numeric, "Continuous", Format("Best", 12), Set Values([30000, 50000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, 1);
		);,
		Title("title")
	), 
);

回复：增加晶圆图中数据点的大小非常感谢您的澄清。是的，我创建了矩形，因为我无法增加圆圈内数据点的大小。如果您能告诉我一种方法，在晶圆图的圆圈内绘制数据点，并根据不同的标准用不同的颜色或图例突出显示它们，那将非常有帮助。谢谢回复：增加晶圆图中数据点的大小

如果你想使用标记，可以选择这样的

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("x", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("y", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				mstate = Color State("Red");
			,
				mstate = Color State("Black");
			);
			xx = Matrix(:x);
			yy = Matrix(:y);
			Marker(mstate, xx, yy);
		);
	)
);

但你也可以使用圆圈，这样可能会更灵活

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				Fill Color("Red");
				Pen Color("Blue");
			,
				Fill Color("Black");
				Pen Color("Black");
			);
			Circle(Eval List({:x, :y}), 10000, "FILL")
		);
	)
);

还有一个选择可能是在图形生成器中完成大部分工作，具体取决于您想要实现的目标。

回复：增加晶圆图中数据点的大小

非常感谢 Jthi 它完美地按照我想要的方式工作