899608_it-IT

liliconcom

Aumentare la dimensione dei punti dati nella mappa wafer

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			pcolor = color_list[1];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, filled_rect);
		);,
		Title(" Lot: " || sdt:lot_id[p] || " Route: " || sdt:route[p])
	), 
);

Quello sopra è il mio codice JSL. Voglio aumentare la dimensione dei punti all'interno del cerchio e voglio evidenziare il punto se è associato a un'immagine di colore diverso. Potresti aiutarmi con questo?

Modifica (jthi): aggiunta formattazione JSL

Automazione e scriptingRe: Aumentare la dimensione dei punti dati nella mappa wafer

Quali problemi stai riscontrando? Stai riscontrando errori? Quali sono le dimensioni di quali punti? Sembra che nel tuo grafico ci siano solo rettangoli e la loro dimensione è determinata dalla tua tabella dati?

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("left", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("right", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("bottom", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 40000])),
	New Column("top", Numeric, "Continuous", Format("Best", 12), Set Values([30000, 50000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, 1);
		);,
		Title("title")
	), 
);

Re: Aumentare la dimensione dei punti dati nella mappa waferGrazie mille per il chiarimento. Sì, ho creato il rettangolo perché non riesco ad aumentare le dimensioni dei punti dati all'interno del cerchio. Se potessi mostrarmi un modo per tracciare i punti dati all'interno di un cerchio di una mappa wafer ed evidenziarli in base a criteri con colori diversi o tramite legenda, mi faresti un grande favore. Grazie.Re: Aumentare la dimensione dei punti dati nella mappa wafer

Se desideri utilizzare i marcatori, un'opzione simile è

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("x", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("y", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				mstate = Color State("Red");
			,
				mstate = Color State("Black");
			);
			xx = Matrix(:x);
			yy = Matrix(:y);
			Marker(mstate, xx, yy);
		);
	)
);

Ma potresti anche usare i cerchi che potrebbero dare più flessibilità

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				Fill Color("Red");
				Pen Color("Blue");
			,
				Fill Color("Black");
				Pen Color("Black");
			);
			Circle(Eval List({:x, :y}), 10000, "FILL")
		);
	)
);

Un'altra opzione potrebbe essere quella di fare la maggior parte di queste cose nel generatore di grafici, a seconda di ciò che si vuole ottenere.

Re: Aumentare la dimensione dei punti dati nella mappa wafer

Grazie mille Jthi Ha funzionato perfettamente come volevo