899608_de-DE

liliconcom

Erhöhen Sie die Größe der Datenpunkte in der Wafer-Map

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			pcolor = color_list[1];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, filled_rect);
		);,
		Title(" Lot: " || sdt:lot_id[p] || " Route: " || sdt:route[p])
	), 
);

Das Obige ist mein JSL-Code. Ich möchte die Größe der Punkte innerhalb des Kreises vergrößern und die Punkte hervorheben, wenn ihnen ein Bild in einer anderen Farbe zugeordnet ist. Könnten Sie mir bitte dabei helfen?

Bearbeiten (jthi): JSL-Formatierung hinzugefügt

Automatisierung und SkriptingBetreff: Größe der Datenpunkte in der Wafer-Map erhöhen

Welche Probleme treten auf? Erhalten Sie Fehlermeldungen? Welche Punktgrößen gibt es? Ihr Diagramm scheint nur Rechtecke zu enthalten, deren Größe durch Ihre Datentabelle bestimmt wird?

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("left", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("right", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("bottom", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 40000])),
	New Column("top", Numeric, "Continuous", Format("Best", 12), Set Values([30000, 50000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");
 
		For(i = 1, i <= N Rows(pdt), i++,
			xleft = pdt:left[i];
			xright = pdt:right[i];
			ybottom = pdt:bottom[i];
			ytop = pdt:top[i];
			If(pdt:defect_images_count[i] > 0,
				Pen Color("red"),
				Pen Color("Black")
			);
			If(pdt:defect_images_count[i] > 0,
				Fill Color("red"),
				Fill Color("Black")
			);
			Rect(xleft, ytop, xright, ybottom, 1);
		);,
		Title("title")
	), 
);

Betreff: Größe der Datenpunkte in der Wafer-Map erhöhenVielen Dank für die Klarstellung. Ja, ich habe das Rechteck erstellt, da ich die Größe der Datenpunkte im Kreis nicht vergrößern kann. Wenn Sie mir eine Möglichkeit zeigen könnten, die Datenpunkte in einem Kreis einer Waferkarte darzustellen und sie je nach Kriterien in verschiedenen Farben oder Legenden hervorzuheben, wäre das eine große Hilfe. Danke.Betreff: Größe der Datenpunkte in der Wafer-Map erhöhen

Wenn Sie Marker verwenden möchten, ist so etwas eine Option

Names Default To Here(1);

pdt = New Table("Untitled",
	Add Rows(2),
	Compress File When Saved(1),
	New Column("x", Numeric, "Continuous", Format("Best", 12), Set Values([10000, 50000])),
	New Column("y", Numeric, "Continuous", Format("Best", 12), Set Values([3000, 70000])),
	New Column("defect_images_count", Numeric, "Continuous", Format("Best", 12), Set Values([0, 1]))
);

xres = 1000;
yres = 1000;
xmin = -150000;
xmax = 150000;
ymin = -150000;
ymax = 150000;

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				mstate = Color State("Red");
			,
				mstate = Color State("Black");
			);
			xx = Matrix(:x);
			yy = Matrix(:y);
			Marker(mstate, xx, yy);
		);
	)
);

Sie können aber auch Kreise verwenden, die mehr Flexibilität bieten könnten

nw = New Window("BSS_Wafermap", 
	gb = Graph Box(
		framesize(xres, yres),
		X Scale(xmin, xmax),
		Y Scale(ymin, ymax),
		Fill Color("lightgray");
		Pen Color("Blue");
		Circle({0, 0}, 150000, "FILL");

		Marker Size(100);
		xx = [];
		yy = [];
		For Each Row(pdt,
			If(:defect_images_count > 0,
				Fill Color("Red");
				Pen Color("Blue");
			,
				Fill Color("Black");
				Pen Color("Black");
			);
			Circle(Eval List({:x, :y}), 10000, "FILL")
		);
	)
);

Und eine weitere Möglichkeit könnte darin bestehen, das meiste davon im Graph Builder zu erledigen, je nachdem, was Sie erreichen möchten.

Betreff: Größe der Datenpunkte in der Wafer-Map erhöhen

Tausend Dank, Jthi. Es hat perfekt funktioniert, so wie ich es wollte.