899515_zh-TW

liliconcom

在 JSL 圖形中使用新增元素時如何用輪廓取代原始點

下面的 JSL 程式碼嘗試使用 add Element 方法在右側圖表上顯示輪廓圖。但是，由於 add Element 本身就是一個 Add Element 操作，它無法移除或取代右側圖表上原始的 Points 格式，導致產生的圖像與下圖不同。原始 Points 會與新增的輪廓圖一起保留。由於 X 軸只能在之後添加，那麼有沒有辦法在仍然使用 add Element 的同時移除原始的 Points 格式呢？

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
	Size( 488, 352 ),
	Show Control Panel( 0 ),
	Fit to Window( "Off" ),
	Variables( Y( :weight ), Overlay( :age ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 21 ) ), Points( X, Y, Legend( 23 ) ) ), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable( {:height, Role( "X" )} );
gb << Add Variable( {:Height, Role( "X" )} );
gb << Add Element( 1, 1, {Type( "Points" ), X, Y} );
gb << Add Element( 2, 1, {Type( "Contour" ), X, Y} );

自動化和腳本回覆：在 JSL 圖表中使用新增元素時如何用輪廓取代原始點

您可以刪除點元素

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

或者你可以建立圖形生成器表達式來考慮到這一點

回覆：在 JSL 圖表中使用新增元素時如何用輪廓取代原始點

我有兩個問題想問：
（1）為什麼元素（2, 1, 1）被刪除兩次？
前兩個數字代表圖中的位置，但我還不明白第三個數值的意思。

（2）從新的輸出圖中，我注意到 X 和 Y 軸的限值不同。如何才能使左右兩側的 X 軸限值自動相同？

回覆：如何在 JSL 圖表中使用新增元素時用輪廓替換原始點

1. 即使您沒有 x 軸，您也已經在圖表中添加了點 -> 您最終可能會得到比您想像的更多的點圖。

運行圖形建構器腳本->複製腳本

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Points(Y, Legend(21)), Points(Y, Legend(23)))
);

運行<<新增變數->複製腳本

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(21)), Points(X, Y, Legend(23)))
);

運行<<新增變數->複製腳本

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1), Points(X, Y, Legend(24)), Points(X, Y, Legend(25)))
);

</CODE>Run << Remove Element -> copy script</P> <BR /> <BR /> <PRE><CODE class=" language-jsl">Graph Builder( Size(488, 352), Show Control Panel(0), Fit to Window("Off"), Variables(X(:height), X(:height), Y(:weight), Overlay(:age)), Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), Elements(Position(2, 1), Points(X, Y, Legend(25))) );

運行<<刪除元素->複製腳本

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1))
);

等等。

如果你使用盡可能完整的圖表建立器，你將獲得更大的成功機會

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 393),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(2)))
);

gb << Add Variable({:Height, Role("X"), Position(2)});
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

2. 您可以使用腳本調整 x 軸（由於等高線圖比點需要更多空間，因此軸有所不同）

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

min2 = Report(gb)[AxisBox(3)] << get min;
max2 = Report(gb)[AxisBox(3)] << get max;
Report(gb)[AxisBox(1)] << Min(min2) << Max(max2);