899515_ja-JP

liliconcom

JSL グラフで要素を追加する際に元の点を等高線に置き換える方法

以下のJSLコードは、add Elementメソッドを使用して右側のグラフに等高線プロットを表示しようとしています。しかし、add Elementは要素の追加操作であるため、右側のグラフの元のポイント形式を削除または置換することができず、生成される画像は下の図とは異なります。元のポイントは、追加された等高線と共にそのまま残ります。X軸は後からしか追加できないため、add Elementを使用しながら元のポイント形式を削除する方法はありますか？

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
	Size( 488, 352 ),
	Show Control Panel( 0 ),
	Fit to Window( "Off" ),
	Variables( Y( :weight ), Overlay( :age ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 21 ) ), Points( X, Y, Legend( 23 ) ) ), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable( {:height, Role( "X" )} );
gb << Add Variable( {:Height, Role( "X" )} );
gb << Add Element( 1, 1, {Type( "Points" ), X, Y} );
gb << Add Element( 2, 1, {Type( "Contour" ), X, Y} );

自動化とスクリプトRe: JSL グラフで要素を追加する際に元の点を輪郭線に置き換える方法

ポイント要素を削除できます

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

あるいは、これを考慮してグラフビルダー式を構築することもできます

Re: JSL グラフで要素を追加する際に元の点を輪郭線に置き換える方法

質問が2つあります。
（１）なぜ要素（２，１，１）が２回削除されるのですか？
最初の 2 つの数字はグラフ内の位置を表しますが、3 番目の値の意味はまだわかりません。

（2）新しい出力グラフを見ると、X軸とY軸のX軸範囲が異なっていることに気づきました。左右のX軸範囲を自動的に同じにするにはどうすればよいでしょうか？

Re: JSL グラフで要素を追加する際に元の点を輪郭線に置き換える方法

1. x 軸がないにもかかわらず、グラフにすでにポイントが追加されています -> 思ったよりも多くのポイント グラフが作成される可能性があります。

グラフビルダースクリプトを実行 -> スクリプトをコピー

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Points(Y, Legend(21)), Points(Y, Legend(23)))
);

実行 << 変数の追加 -> スクリプトのコピー

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(21)), Points(X, Y, Legend(23)))
);

実行 << 変数の追加 -> スクリプトのコピー

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1), Points(X, Y, Legend(24)), Points(X, Y, Legend(25)))
);

</CODE>Run << Remove Element -> copy script</P> <BR /> <BR /> <PRE><CODE class=" language-jsl">Graph Builder( Size(488, 352), Show Control Panel(0), Fit to Window("Off"), Variables(X(:height), X(:height), Y(:weight), Overlay(:age)), Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), Elements(Position(2, 1), Points(X, Y, Legend(25))) );

<<要素の削除 -> コピースクリプトを実行

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1))
);

等々。

できるだけ完全なグラフビルダーを使用すると、成功する可能性がはるかに高くなります。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 393),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(2)))
);

gb << Add Variable({:Height, Role("X"), Position(2)});
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

2. スクリプトを使用して x 軸を調整できます (等高線プロットはポイントよりも多くのスペースを必要とするため、軸は異なります)

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

min2 = Report(gb)[AxisBox(3)] << get min;
max2 = Report(gb)[AxisBox(3)] << get max;
Report(gb)[AxisBox(1)] << Min(min2) << Max(max2);