899515_it-IT

liliconcom

Come sostituire i punti originali con il contorno quando si utilizza Aggiungi elemento nei grafici JSL

Il codice JSL seguente tenta di utilizzare il metodo "add Element" per visualizzare un grafico a curve di livello sul grafico a destra. Tuttavia, poiché "add Element" è un'operazione di tipo "Add Element", non può rimuovere o sostituire il formato originale dei punti sul grafico a destra, con il risultato che l'immagine generata risulta diversa dalla figura sottostante. I punti originali rimangono insieme al grafico a curve di livello aggiunto. Poiché l'asse X può essere aggiunto solo in un secondo momento, esiste un modo per rimuovere il formato originale dei punti continuando a utilizzare "add Element"?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
	Size( 488, 352 ),
	Show Control Panel( 0 ),
	Fit to Window( "Off" ),
	Variables( Y( :weight ), Overlay( :age ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 21 ) ), Points( X, Y, Legend( 23 ) ) ), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable( {:height, Role( "X" )} );
gb << Add Variable( {:Height, Role( "X" )} );
gb << Add Element( 1, 1, {Type( "Points" ), X, Y} );
gb << Add Element( 2, 1, {Type( "Contour" ), X, Y} );

Automazione e scriptingRe: Come sostituire i punti originali con il contorno quando si utilizza Aggiungi elemento nei grafici JSL

È possibile rimuovere l'elemento punto

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

oppure potresti creare l'espressione del generatore di grafici per tenerne conto

Re: Come sostituire i punti originali con il contorno quando si utilizza Aggiungi elemento nei grafici JSL

Ho due domande da porre:
(1) Perché gli elementi (2, 1, 1) vengono cancellati due volte?
I primi due numeri rappresentano la posizione nel grafico, ma non ho ancora capito il significato del terzo valore.

(2) Dal nuovo grafico di output, ho notato che i limiti dell'asse X per X e Y sono diversi. Come posso rendere automaticamente uguali i limiti dell'asse X sia sul lato sinistro che su quello destro?

Re: Come sostituire i punti originali con il contorno quando si utilizza Aggiungi elemento nei grafici JSL

1. Hai già aggiunto punti al tuo grafico anche se non hai l'asse x -> potresti ritrovarti con più grafici di punti di quanto pensi.

Esegui lo script del generatore di grafici -> copia lo script

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Points(Y, Legend(21)), Points(Y, Legend(23)))
);

Esegui << Aggiungi variabile -> Copia script

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(21)), Points(X, Y, Legend(23)))
);

Esegui << Aggiungi variabile -> Copia script

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1), Points(X, Y, Legend(24)), Points(X, Y, Legend(25)))
);

</CODE>Run << Remove Element -> copy script</P> <BR /> <BR /> <PRE><CODE class=" language-jsl">Graph Builder( Size(488, 352), Show Control Panel(0), Fit to Window("Off"), Variables(X(:height), X(:height), Y(:weight), Overlay(:age)), Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), Elements(Position(2, 1), Points(X, Y, Legend(25))) );

Esegui << Rimuovi elemento -> copia script

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1))
);

e così via.

Puoi darti molte più possibilità di successo se usi un generatore di grafici il più completo possibile

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 393),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(2)))
);

gb << Add Variable({:Height, Role("X"), Position(2)});
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

2. È possibile regolare l'asse x con uno script (gli assi sono diversi poiché il grafico dei contorni necessita di più spazio rispetto ai punti)

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

min2 = Report(gb)[AxisBox(3)] << get min;
max2 = Report(gb)[AxisBox(3)] << get max;
Report(gb)[AxisBox(1)] << Min(min2) << Max(max2);