899515_de-DE

liliconcom

So ersetzen Sie Originalpunkte durch Konturen, wenn Sie „Element hinzufügen“ in JSL-Diagrammen verwenden

Der folgende JSL-Code versucht, mit der Methode „Element hinzufügen“ ein Konturdiagramm im rechten Diagramm anzuzeigen. Da „Element hinzufügen“ jedoch eine Operation zum Hinzufügen von Elementen ist, kann das ursprüngliche Punkteformat im rechten Diagramm weder entfernt noch ersetzt werden. Das generierte Bild unterscheidet sich daher von der folgenden Abbildung. Die ursprünglichen Punkte bleiben zusammen mit der hinzugefügten Kontur erhalten. Da die X-Achse erst nachträglich angehängt werden kann, gibt es eine Möglichkeit, das ursprüngliche Punkteformat zu entfernen und gleichzeitig „Element hinzufügen“ zu verwenden?

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
	Size( 488, 352 ),
	Show Control Panel( 0 ),
	Fit to Window( "Off" ),
	Variables( Y( :weight ), Overlay( :age ) ),
	Elements( Position( 1, 1 ), Points( X, Y, Legend( 21 ) ), Points( X, Y, Legend( 23 ) ) ), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable( {:height, Role( "X" )} );
gb << Add Variable( {:Height, Role( "X" )} );
gb << Add Element( 1, 1, {Type( "Points" ), X, Y} );
gb << Add Element( 2, 1, {Type( "Contour" ), X, Y} );

Automatisierung und SkriptingBetreff: So ersetzen Sie Originalpunkte durch Konturen, wenn Sie „Element hinzufügen“ in JSL-Diagrammen verwenden

Sie können das Punktelement entfernen

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

oder Sie könnten den Graph Builder-Ausdruck erstellen, um dies zu berücksichtigen

Betreff: So ersetzen Sie Originalpunkte durch Konturen, wenn Sie „Element hinzufügen“ in JSL-Diagrammen verwenden

Ich habe zwei Fragen:
(1) Warum werden die Elemente (2, 1, 1) zweimal gelöscht?
Die ersten beiden Zahlen stellen die Position im Diagramm dar, aber die Bedeutung des dritten Werts verstehe ich noch nicht.

(2) Im neuen Ausgabediagramm ist mir aufgefallen, dass die X-Achsengrenzen für X und Y unterschiedlich sind. Wie kann ich die X-Achsengrenzen auf der linken und rechten Seite automatisch angleichen?

Betreff: So ersetzen Sie Originalpunkte durch Konturen, wenn Sie „Element hinzufügen“ in JSL-Diagrammen verwenden

1. Sie haben Ihrem Diagramm bereits Punkte hinzugefügt, obwohl Sie keine X-Achse haben -> Sie erhalten am Ende möglicherweise mehr Punktediagramme als Sie denken.

Graph Builder-Skript ausführen -> Skript kopieren

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Points(Y, Legend(21)), Points(Y, Legend(23)))
);

Ausführen << Variable hinzufügen -> Skript kopieren

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(21)), Points(X, Y, Legend(23)))
);

Ausführen << Variable hinzufügen -> Skript kopieren

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1), Points(X, Y, Legend(24)), Points(X, Y, Legend(25)))
);

</CODE>Run << Remove Element -> copy script</P> <BR /> <BR /> <PRE><CODE class=" language-jsl">Graph Builder( Size(488, 352), Show Control Panel(0), Fit to Window("Off"), Variables(X(:height), X(:height), Y(:weight), Overlay(:age)), Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), Elements(Position(2, 1), Points(X, Y, Legend(25))) );

Ausführen << Element entfernen -> Skript kopieren

Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), X(:height), Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))),
	Elements(Position(2, 1))
);

und so weiter.

Sie können Ihre Erfolgschancen deutlich erhöhen, wenn Sie einen möglichst vollständigen Graph Builder verwenden.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 393),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(X(:height), Y(:weight), Overlay(:age)),
	Elements(Points(X, Y, Legend(2)))
);

gb << Add Variable({:Height, Role("X"), Position(2)});
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

2. Sie können die X-Achse mit einem Skript anpassen (die Achsen sind unterschiedlich, da das Konturdiagramm mehr Platz benötigt als Punkte).

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(488, 352),
	Show Control Panel(0),
	Fit to Window("Off"),
	Variables(Y(:weight), Overlay(:age)),
	Elements(Position(1, 1), Points(X, Y, Legend(21)), Points(X, Y, Legend(23))), 
		//Elements( Position( 2, 1 ), Contour( X, Y, Legend( 22 ) ) ), 
		
		
);
gb << Add Variable({:height, Role("X")});
gb << Add Variable({:Height, Role("X")});
gb << Remove Element(2, 1, 1);
gb << Remove Element(2, 1, 1);
gb << Add Element(2, 1, {Type("Contour"), X, Y});

min2 = Report(gb)[AxisBox(3)] << get min;
max2 = Report(gb)[AxisBox(3)] << get max;
Report(gb)[AxisBox(1)] << Min(min2) << Max(max2);