896758_zh-TW

liliconcom

在運行圖中廣播 x 軸設定的簡單方法

在「分析」>「品質和流程」>「控製圖」>「運行圖」下，如果繪製多個 Y 變數的運行圖，似乎無法為所有圖表廣播 X 軸設定。這很令人沮喪。有什麼解決方法嗎？

品質與工藝工程回覆：在運行圖中廣播 x 軸設定的簡單方法

似乎運行圖表實際上不允許您執行任何可以使用帶有軸的 JMP 平台正常執行的操作，並且當您將滑鼠懸停在 x 軸上時，它會顯示“對於從資料視圖創建的圖形，編輯模式已停用”...因此您可能必須依賴腳本。

回覆：在運行圖中廣播 x 軸設定的簡單方法

是的，JSL 似乎是唯一的選擇，這很令人失望。我為此創建了一個願望清單https://community.jmp.com/t5/JMP-Wish-List/Allow-right-click-actions-and-broadcasting-of-Run-Chart/idi-p/896865#M7631

回覆：在運行圖中廣播 x 軸設定的簡單方法

如果你不介意弄亂你的剪貼板，那麼幸運的是，編寫腳本會非常簡單（如果 axisbox 總是這樣表現的話）

Names Default To Here(1); 

dt = Open("$SAMPLE_DATA/Big Class.jmp");
dt << New Formula Column(
	Operation(Category("Combine"), "Product"),
	Columns(:height, :weight)
);

ccb = dt << Control Chart Builder(
	Show Two Shewhart Charts(0),
	Show Limit Summaries(0),
	Variables(Y(:height, :weight, "height*weight"n)),
	Chart(
		Points(Statistic("Individual")),
		Limits(Sigma("Moving Range"), Show Lower Limit(0), Show Upper Limit(0))
	),
	Show Control Panel(0)
);
Report(ccb)[AxisBox(1)] << Max(60); // demo purposes


Report(ccb)[AxisBox(1)] << Copy Axis Settings;

abs = (Report(ccb) << XPath("//AxisBox"));
xabs = abs[3::N Items(abs)::2];
xabs << Paste Axis Settings;

或者我認為你可以使用<<複製腳本然後發送該設定列表

ascript = Report(ccb)[AxisBox(1)] << Get Script;
abs = (Report(ccb) << XPath("//AxisBox"));
xabs = abs[3::N Items(abs)::2];
Eval(EvalExpr(
	Send(xabs, Expr(ascript))
));