895395_zh-CN

liliconcom

如何改变通过添加图形脚本添加的形状/文本？

假设我想使用“添加图形脚本”在图表上添加自定义文本或形状：

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Window( "Example",
	gb = Graph Builder(
		Size( 528, 456 ),
		Show Control Panel( 0 ),
		Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
		Elements( Points( X, Y, Legend( 9 ) ), Smoother( X, Y, Legend( 10 ) ) ), 
	
	)
);
rgb = gb << Report;
framebox = rgb << XPATH( "//FrameBox" );
framebox << Add Graphics Script(
	"Front",
	Description( "CustomText" ),
	{
		Text( "left", 0.05, {100, 55}, "This is my custom text" ) ; 
		Line( {80, 50}, {160, 65} )
	}
);

我之后该如何更改字体或字体大小？如何更改线条颜色或样式？如何获取它们的引用来执行隐藏、显示、删除等操作？

自动化和脚本回复：如何改变通过添加图形脚本添加的形状/文本？

以下是直接从脚本索引中获取的示例

删除图形脚本

信息

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
framebox = rbiv[frame box( 1 )];
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {1.0, 0.5, 0.0} );
	Polygon( [60, 72, 57], [75, 120, 120] );
);
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {0.0, 0.5, 1.0} );
	Polygon( [60, 72, 57], [150, 120, 120] );
);
Wait( 2 );
framebox << Remove Graphics Script( 2 );

回复：如何改变通过添加图形脚本添加的形状/文本？

好的，这涵盖了其中的一部分内容。

如果我想让文字变小怎么办？或者变成蓝色？或者斜体？该如何实现？

如果我想要线条是虚线并且是蓝色的怎么办？

回复：如何改变通过添加图形脚本添加的形状/文本？

脚本索引对所有这些问题都有答案（文本大小、文本字体、文本颜色）

Names Default To Here(1);
New Window("Example",
	Graph Box(
		Text Size(100);
		Text Color("Blue");
		Text Font("", "italic");
		Text({50, 20}, "label");
	)
);

画笔颜色()、线条样式()

Names Default To Here(1);
New Window("Line Style Example",
	Graph Box(
		Frame Size(500, 400),
		Line Style("Dotted");
		Pen Color("Blue");
		Pen Size(2);
		Line([10 30 90], [88 22 44]);
	);
);

回复：如何改变通过添加图形脚本添加的形状/文本？

剩下的我都弄清楚了。它们在图形脚本中是单独的命令，而不是“文本”或“线条”的属性或消息。

回复：如何改变通过添加图形脚本添加的形状/文本？

你好@txnelson ，

这是一个很好的例子，但我认为你应该写的是“删除图形脚本”而不是“删除图形脚本”。

顺便说一下，脚本索引现已上线。https /jsl.jmp.com

您可以直接链接到功能和消息：

https://jsl.jmp.com/All%20Categories/Display%20Boxes/FrameBox.html#remove-graphics-script

您无法像在 JMP 的脚本索引中那样直接从网页运行，但每个脚本的右上角都有一个方便的复制按钮。在线脚本索引可以帮助 JMP Live 用户在未安装 JMP 的设备上编辑脚本。

我希望你觉得这有用。

~约翰