그래픽 스크립트 추가를 통해 추가된 모양/텍스트를 어떻게 변경하나요?"그래픽 스크립트 추가"를 사용하여 그래프에 사용자 정의 텍스트나 모양을 추가하고 싶다고 가정해 보겠습니다.
Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
New Window( "Example",
gb = Graph Builder(
Size( 528, 456 ),
Show Control Panel( 0 ),
Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
Elements( Points( X, Y, Legend( 9 ) ), Smoother( X, Y, Legend( 10 ) ) ),
)
);
rgb = gb << Report;
framebox = rgb << XPATH( "//FrameBox" );
framebox << Add Graphics Script(
"Front",
Description( "CustomText" ),
{
Text( "left", 0.05, {100, 55}, "This is my custom text" ) ;
Line( {80, 50}, {160, 65} )
}
);
나중에 글꼴이나 글꼴 크기를 어떻게 변경하나요? 선 색상이나 스타일은 어떻게 변경하나요? 숨기기, 표시, 삭제 등의 작업을 할 때 참조를 어떻게 가져오나요?
자동화 및 스크립팅Re: 그래픽 스크립트 추가를 통해 추가된 모양/텍스트를 어떻게 변경하나요?다음은 스크립팅 인덱스에서 직접 가져온 예입니다.
그래픽 스크립트 삭제
메시지
Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
framebox = rbiv[frame box( 1 )];
framebox << Add Graphics Script(
Transparency( 0.5 );
Fill Color( {1.0, 0.5, 0.0} );
Polygon( [60, 72, 57], [75, 120, 120] );
);
framebox << Add Graphics Script(
Transparency( 0.5 );
Fill Color( {0.0, 0.5, 1.0} );
Polygon( [60, 72, 57], [150, 120, 120] );
);
Wait( 2 );
framebox << Remove Graphics Script( 2 );
Re: 그래픽 스크립트 추가를 통해 추가된 모양/텍스트를 어떻게 변경하나요?네, 일부는 다루겠습니다.
처음부터 텍스트를 더 작게 하고 싶다면 어떻게 해야 할까요? 파란색 으로? 아니면 기울임체로 ? 어떻게 해야 할까요?
그리고 선을 점선으로 표현하고 싶고 파란색으로 표현하고 싶다면 어떻게 해야 하나요?
Re: 그래픽 스크립트 추가를 통해 추가된 모양/텍스트를 어떻게 변경하나요?스크립팅 인덱스에는 이 모든 것(텍스트 크기, 텍스트 글꼴, 텍스트 색상)에 대한 답변이 있습니다.
Names Default To Here(1);
New Window("Example",
Graph Box(
Text Size(100);
Text Color("Blue");
Text Font("", "italic");
Text({50, 20}, "label");
)
);
펜 색상(), 선 스타일()
Names Default To Here(1);
New Window("Line Style Example",
Graph Box(
Frame Size(500, 400),
Line Style("Dotted");
Pen Color("Blue");
Pen Size(2);
Line([10 30 90], [88 22 44]);
);
);
Re: 그래픽 스크립트 추가를 통해 추가된 모양/텍스트를 어떻게 변경하나요?나머지는 알아냈어요. 그래픽 스크립트에서 별도의 명령으로 제공됩니다. "텍스트"나 "선"의 속성이나 메시지로 제공되는 것이 아닙니다.
Re: 그래픽 스크립트 추가를 통해 추가된 모양/텍스트를 어떻게 변경하나요?안녕하세요 @txnelson ,
좋은 예이긴 한데, "그래픽 스크립트 삭제" 대신 "그래픽 스크립트 제거"라고 쓰려고 했던 것 같습니다.
그런데 스크립팅 인덱스가 지금 온라인에 올라와 있습니다. https://jsl.jmp.com
다음과 같이 함수와 메시지에 직접 연결할 수 있습니다.
https://jsl.jmp.com/All%20Categories/Display%20Boxes/FrameBox.html#remove-graphics-script
JMP의 스크립팅 인덱스처럼 웹 페이지에서 바로 실행할 수는 없지만, 오른쪽 상단에 각 스크립트의 편리한 복사 버튼이 있습니다. 온라인 스크립팅 인덱스를 통해 JMP Live 사용자는 JMP가 설치되지 않은 기기에서도 스크립트를 편집할 수 있습니다.
이 글이 도움이 되길 바랍니다.
~존
