895395_it-IT

liliconcom

Come modificare le forme/il testo aggiunti tramite Aggiungi script grafico?

Supponiamo che io voglia aggiungere del testo personalizzato o una forma al mio grafico utilizzando "Aggiungi script grafico":

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Window( "Example",
	gb = Graph Builder(
		Size( 528, 456 ),
		Show Control Panel( 0 ),
		Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
		Elements( Points( X, Y, Legend( 9 ) ), Smoother( X, Y, Legend( 10 ) ) ), 
	
	)
);
rgb = gb << Report;
framebox = rgb << XPATH( "//FrameBox" );
framebox << Add Graphics Script(
	"Front",
	Description( "CustomText" ),
	{
		Text( "left", 0.05, {100, 55}, "This is my custom text" ) ; 
		Line( {80, 50}, {160, 65} )
	}
);

Come posso modificare in seguito, ad esempio, il carattere o la dimensione del carattere? Come posso cambiare il colore o lo stile della linea? Come posso ottenere riferimenti a essi per azioni come nascondere, mostrare, eliminare, ecc.?

Automazione e scriptingRe: Come modificare forme/testi aggiunti tramite Aggiungi script grafico?

Ecco un esempio tratto direttamente dall'indice di scripting per

Elimina script grafico

messaggio

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
framebox = rbiv[frame box( 1 )];
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {1.0, 0.5, 0.0} );
	Polygon( [60, 72, 57], [75, 120, 120] );
);
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {0.0, 0.5, 1.0} );
	Polygon( [60, 72, 57], [150, 120, 120] );
);
Wait( 2 );
framebox << Remove Graphics Script( 2 );

Re: Come modificare forme/testi aggiunti tramite Aggiungi script grafico?

Ok, questo è tutto.

E se volessi che il testo fosse più piccolo ? O blu ? O in corsivo ? Come posso ottenere questo risultato?

E se volessi che la linea fosse punteggiata e anche blu?

Re: Come modificare forme/testi aggiunti tramite Aggiungi script grafico?

L'indice di scripting ha la risposta a tutte queste domande (dimensione del testo, carattere del testo, colore del testo)

Names Default To Here(1);
New Window("Example",
	Graph Box(
		Text Size(100);
		Text Color("Blue");
		Text Font("", "italic");
		Text({50, 20}, "label");
	)
);

Colore penna(), Stile linea()

Names Default To Here(1);
New Window("Line Style Example",
	Graph Box(
		Frame Size(500, 400),
		Line Style("Dotted");
		Pen Color("Blue");
		Pen Size(2);
		Line([10 30 90], [88 22 44]);
	);
);

Re: Come modificare forme/testi aggiunti tramite Aggiungi script grafico?

Il resto l'ho capito. Sono disponibili come comandi separati in Graphics Script. Non come proprietà o messaggi per "Testo" o "Linea".

Re: Come modificare forme/testi aggiunti tramite Aggiungi script grafico?

Ciao @txnelson ,

Questo è un ottimo esempio, ma credo che volessi scrivere "Rimuovi script grafico" invece di "Elimina script grafico".

A proposito, lo Scripting Index è ora online. https://jsl.jmp.com

È possibile collegarsi direttamente alle funzioni e ai messaggi:

https://jsl.jmp.com/All%20Categories/Display%20Boxes/FrameBox.html#remove-graphics-script

Non sarà possibile eseguirli direttamente dalla pagina web come avviene dall'Indice degli script in JMP, ma è presente un comodo pulsante di copia per ogni script nell'angolo in alto a destra. L'Indice degli script online può aiutare gli utenti di JMP Live a modificare i propri script su un dispositivo su cui JMP non è installato.

Spero che questo articolo ti sia utile.

~Giovanni