895395_fr-FR

liliconcom

Comment modifier les formes/textes ajoutés via Ajouter un script graphique ?

Disons que je souhaite ajouter du texte personnalisé ou une forme sur mon graphique à l'aide de « Ajouter un script graphique » :

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );

New Window( "Example",
	gb = Graph Builder(
		Size( 528, 456 ),
		Show Control Panel( 0 ),
		Variables( X( :weight ), Y( :height ), Overlay( :sex ) ),
		Elements( Points( X, Y, Legend( 9 ) ), Smoother( X, Y, Legend( 10 ) ) ), 
	
	)
);
rgb = gb << Report;
framebox = rgb << XPATH( "//FrameBox" );
framebox << Add Graphics Script(
	"Front",
	Description( "CustomText" ),
	{
		Text( "left", 0.05, {100, 55}, "This is my custom text" ) ; 
		Line( {80, 50}, {160, 65} )
	}
);

Comment puis-je modifier ultérieurement, par exemple, la police ou la taille ? Comment changer la couleur ou le style des lignes ? Comment obtenir des références pour masquer, afficher, supprimer, etc. ?

Automatisation et scriptsRe : Comment modifier les formes/textes ajoutés via Ajouter un script graphique ?

Voici un exemple tiré directement de l'index de script pour le

Supprimer le script graphique

message

Names Default To Here( 1 );
Open( "$SAMPLE_DATA/Big Class.jmp" );
biv = Bivariate( Y( :weight ), X( :height ), FitLine );
rbiv = biv << report;
framebox = rbiv[frame box( 1 )];
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {1.0, 0.5, 0.0} );
	Polygon( [60, 72, 57], [75, 120, 120] );
);
framebox << Add Graphics Script(
	Transparency( 0.5 );
	Fill Color( {0.0, 0.5, 1.0} );
	Polygon( [60, 72, 57], [150, 120, 120] );
);
Wait( 2 );
framebox << Remove Graphics Script( 2 );

Re : Comment modifier les formes/textes ajoutés via Ajouter un script graphique ?

Ok, cela couvre une partie du sujet.

Et si je souhaite que le texte soit plus petit dès le départ ? Ou bleu ? Ou en italique ? Comment y parvenir ?

Et si je veux que la ligne soit en pointillé et également bleue ?

Re : Comment modifier les formes/textes ajoutés via Ajouter un script graphique ?

L'index de script a la réponse à toutes ces questions (taille du texte, police du texte, couleur du texte)

Names Default To Here(1);
New Window("Example",
	Graph Box(
		Text Size(100);
		Text Color("Blue");
		Text Font("", "italic");
		Text({50, 20}, "label");
	)
);

Couleur du stylo(), Style de ligne()

Names Default To Here(1);
New Window("Line Style Example",
	Graph Box(
		Frame Size(500, 400),
		Line Style("Dotted");
		Pen Color("Blue");
		Pen Size(2);
		Line([10 30 90], [88 22 44]);
	);
);

Re : Comment modifier les formes/textes ajoutés via Ajouter un script graphique ?

J'ai compris le reste. Il s'agit de commandes distinctes dans Graphics Script, et non de propriétés ou de messages pour « Texte » ou « Ligne ».

Re : Comment modifier les formes/textes ajoutés via Ajouter un script graphique ?

Salut @txnelson ,

C'est un excellent exemple, mais je pense que vous vouliez écrire « Supprimer le script graphique » au lieu de « Supprimer le script graphique ».

Au fait, l'index des scripts est désormais en ligne. https://jsl.jmp.com

Vous pouvez créer un lien direct vers les fonctions et les messages :

https://jsl.jmp.com/All%20Categories/Display%20Boxes/FrameBox.html#remove-graphics-script

Vous ne pourrez pas exécuter directement vos scripts depuis la page web comme vous le feriez avec l'index des scripts de JMP, mais un bouton de copie pratique est disponible pour chaque script en haut à droite. L'index des scripts en ligne permet aux utilisateurs de JMP Live de modifier leurs scripts sur un appareil non équipé de JMP.

J'espère que vous trouverez cela utile.

~Jean