895150_fr-FR

liliconcom

Passer dynamiquement un ensemble de colonnes à une fonction de résumé de table

J'ai un flux de travail qui génère un tableau (exemple ci-joint), mais le nombre de colonnes et le nom de ces colonnes à partir de 14 varient en fonction de l'ensemble de données que l'utilisateur final consulte.

La première partie du script fonctionne parfaitement : elle génère une liste des noms de colonnes. Ce qui me pose problème, et qui dépasse tout ce que j'ai pu faire en JSL jusqu'à présent, c'est de renvoyer cette liste à une fonction de résumé de table. En toute transparence, j'ai essayé de résoudre ce problème avec MS Copilot (l'agent AI pointait vers la documentation JMP), sans succès.

//num cols
dt = Data Table( "plate_data_wide_for_dynamic_summary Anonymized" );
nCols = N Col( dt );

//empty list of colnames, populate with col names from 14 to end of table
colnames = {};
For( i = 14, i <= nCols, i++,
	Insert Into( colnames, Column( dt, i ) << Get Name )
);

//create summary expression with dynamic column placeholder
summaryExpr = Expr(
	Data Table( "plate_data_wide_for_dynamic_summary Anonymized" ) << Summary(
		Group(
			:X__1, :X__3, :X__10
		),
		__DYNAMIC_COLUMNS__,
		Freq( "None" ),
		Weight( "None" ),
		output table name( "Summarized by PC plate_well wide" )
	)
);

//create list of summary statistics and columns to pass to summary function
dynamicCols = {};
For( i = 1, i <= N Items( colnames ), i++,
	Insert Into( dynamicCols, Eval Expr( Median( As Column( dt, colnames[i] ) ) ) )
);

//pass dynamicCols list to summary expression and evaluate
Insert Into( summaryExpr[1][2], dynamicCols );
Eval( summaryExpr );

Automatisation et scriptsRe : Passage dynamique d'un ensemble de colonnes à une fonction de résumé de table

Je crois que cela vous donne ce que vous voulez

Names Default to Here( 1 );
dt = Data Table( "plate_data_wide_for_dynamic_summary Anonymized" );
nCols = N Col( dt );

//empty list of colnames, populate with col names from 14 to end of table
colnames = dt << get column names( string ); //num cols

staticNames = {"X__1", "X__3", "X__10"};

For Each( {sName}, staticNames, Try( Remove From( colnames, Contains( colnames, sName ), 1 ) ) );

//create summary expression with dynamic column placeholder
Eval(
	Eval Expr(
		Data Table( "plate_data_wide_for_dynamic_summary Anonymized" ) <<
		Summary(
			Group( Expr( staticNames ) ),
			Median( Expr( colnames ) ),
			Freq( "None" ),
			Weight( "None" ),
			output table name( "Summarized by PC plate_well wide" )
		)
	)
);

Re : Passage dynamique d'un ensemble de colonnes à une fonction de résumé de table

Super Jim, merci ! J'ai apporté une légère modification pour passer les noms de colonnes 14 à la fin, plutôt que celles qui n'étaient pas utilisées pour le regroupement. Voici la version finale :

Names Default to Here( 1 );
dt = Data Table( "plate_data_wide_for_dynamic_summary Anonymized" );
nCols = N Col( dt );

//empty list of colnames, populate with col names from 14 to end of table
colnames = {};
For( i = 14, i <= nCols, i++,
	Insert Into( colnames, Column( dt, i ) << Get Name )
);

GroupColNames = {"X__1", "X__3", "X__10"};



//create summary expression with dynamic column insertion
Eval(
	Eval Expr(
		Data Table( "plate_data_wide_for_dynamic_summary Anonymized" ) <<
		Summary(
			Group( Expr( GroupColNames ) ),
			Median( Expr( colnames ) ),
			Freq( "None" ),
			Weight( "None" ),
			output table name( "Summarized by PC plate_well wide" )
		)
	)
);