893833_es-ES

liliconcom

Intentando crear un script JSL y obtener el máximo provecho del diseño RSM

¡Hola!

Soy nuevo en JMP. Estoy usando la versión de prueba para estudiantes y quiero usar el script JSL para usar el diseño RSM. Aquí les muestro lo que he logrado...

Names Default To Here( 1 );

// Here are the factors and the ranges
factors = {
	{"X1", 0, 1, "Continuous"},
	{"X2", 0, 1, "Continuous"},
	{"X3", 0, 1, "Continuous"}
};

rsm = DOE( Response Surface Design );

// Add a response
rsm << AddResponse( Minimize, "Y");

// Add the factors. We will need to overwrite the defaults
// overwrite the two built‑ins
For( i = 1, i <= Min( N Items( factors ), 2 ), i++,
	rsm << Change Factor Settings( i, factors[i][2], factors[i][3], factors[i][1] );
);

// add any remaining
For( i = 3, i <= N Items( factors ), i++,
	rsm << Add Factor( Continuous, factors[i][2], factors[i][3], factors[i][1], 0 );
);

rsm << Set Random Seed( 30624700 );
rsm << Make Design( 2 );
rsm << Set Axial Choice( 4 );
rsm << Center Points( 0 );
rsm << Make Table;

dt = Current Data Table();

// Set the response here
yvals = { 1.23, 0.98, 1.05, 0.76, 1.12, 1.23, 0.98, 1.05, 0.76, 1.12, 1.23, 0.98, 1.05, 0.76};
dt:Y << Set Values( yvals );

///////////////////////////
/////// Fit the RSM ///////
///////////////////////////

// Fit the RSM
fm = dt << Fit Model;
fls = fm <<  Run;

Logré obtener la tabla de datos con los factores e insertar algunos valores ficticios. Puedo ajustar el modelo cuadrático y ejecutarlo. Parece que obtengo algún tipo de objeto de informe, pero quiero usar "Prediction Profiler", "Maximize desairability" y "Remember" el óptimo. Quiero agregar esos factores óptimos sugeridos a la tabla de datos. Todas estas palabras clave se encuentran en el índice de scripting, pero no logro entender cómo hacer que funcione en JSL.

¡Cualquier ayuda sería muy apreciada! Muchas gracias.

Análisis y modelado de datos básicosRe: Intentando crear un script JSL y obtener el máximo provecho del diseño RSM

Creo que debes encontrar una referencia a la plataforma del generador de perfiles. Puedes hacerlo buscando la referencia al cuadro de esquema del generador de perfiles de predicción y luego usando "Obtener objeto programable".

profiler_ob = (Report(fls) << XPath("//OutlineBox[@helpKey='Profiler']"))[1];
pf = profiler_ob << Get Scriptable Object;

También debería poder obtener la referencia mediante la suscripción al informe.

profiler_ob = Report(fls)[OutlineBox("Prediction Profiler")];
pf = profiler_ob << Get Scriptable Object;

Después de eso, puedes usar pf como lo harías con el objeto Profiler, por ejemplo

pf << Maximize Desirability;

Re: Intentando crear un script JSL y obtener el máximo provecho del diseño RSM

¡Increíble! ¡Gracias!