892762_es-ES

liliconcom

cuadro

Buen día,

He superpuesto 3 variables en el eje Y.

¿Es posible añadir una línea vertical para conectar el mínimo con el máximo de cada identificador en el eje X? Deberíamos poder elegir el color, el grosor y la transparencia de la línea vertical.

Vea la imagen con un ejemplo en el círculo.

Atentamente

Exploración y visualización de datosRe: gráfico

Podrías intentar usar la barra de error de rango

O puede agregar un gráfico de barras de intervalo y deshabilitar el valor "medio" (esto podría requerir algunos cálculos/columnas adicionales)

Y luego, por supuesto, existe la opción de scripting utilizando script gráfico, que es más complicado.

Re: gráfico

He aquí un posible ejemplo de opción con script

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Formula Column(Operation(Category("Aggregate"), "Minimum"), Columns(:height), Group By(:age));
dt << New Formula Column(Operation(Category("Aggregate"), "Maximum"), Columns(:height), Group By(:age));

gb = dt << Graph Builder(
	Size(525, 448),
	Show Control Panel(0),
	Variables(
		X(:age),
		Y(:height),
		Y(:"Maximum[height][age]"n, Position(1)),
		Y(:"Minimum[height][age]"n, Position(1))
	),
	Elements(Points(X, Y(1), Y(2), Y(3), Legend(3), Summary Statistic("Mean")))
);



segs = Report(gb)[FrameBox(1)] << Find Segs();
ys = [];
xs = {};
For Each({seg}, segs, 
	If(seg << Class Name == "MarkerSeg", 
		ys = ys |/ (seg << get y values)`;
		Insert Into(xs, seg << get x values);
	)
);

For Each({{ymin, ymax, x}}, Across(V Min(ys), V Max(ys), xs[1]), 
	Eval(EvalExpr(
		Report(gb)[FrameBox(1)] << Add Graphics Script(
			"Back",
			Pen Color("Purple");
			Pen Size(20);
			Transparency(0.2);
			V Line(Expr(x), Expr(ymin), Expr(ymax));
		);
	));
);

Write();

Este ejemplo "simple" no funcionará con filtros.

Re: gráfico

Y luego está Marker Draw Expr, donde puedes controlar el color y la transparencia de la leyenda y el ancho de la expresión de dibujo.

Ver más...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Formula Column(Operation(Category("Aggregate"), "Minimum"), Columns(:height), Group By(:age));
dt << New Formula Column(Operation(Category("Aggregate"), "Maximum"), Columns(:height), Group By(:age));

gb = dt << Graph Builder(
	Size(746, 818),
	Show Control Panel(0),
	Variables(
		X(:age),
		Y(:height),
		Y(:"Maximum[height][age]"n, Position(1)),
		Y(:"Minimum[height][age]"n, Position(1))
	),
	Elements(
		Points(X, Y(1), Y(2), Y(3), Legend(3), Summary Statistic("Mean")),
		Points(X, Y(1), Legend(4), Summary Statistic("Mean"))
	),
	Local Data Filter(Add Filter(columns(:age), Display(:age, N Items(6)))),
	SendToReport(
		Dispatch({}, "400", ScaleBox,
			{Legend Model(
				4,
				Properties(
					0,
					{Line Color(35), Transparency(0.2)},
					Item ID("Mean(height)", 1)
				)
			)}
		)
	)
);

frame = Report(gb)[FrameBox(1)];
seg = (frame << FindSeg(Marker Seg(4)));
seg << Set Marker Draw Expr(
	Function({this seg, this row, x, y, size, row state},
		size = 0.1;
		Rect(
			x - size,
			:"Maximum[height][age]"n[this row], 
			x + size,
			:"Minimum[height][age]"n[this row],
			1
		);
	);
);