892762_ko-KR

liliconcom

차트

좋은 아침이에요,

Y축에 3개의 변수를 중첩했습니다.

X축에서 각 식별자의 최소값과 최대값을 연결하는 수직선을 추가할 수 있을까요? 수직선의 색상, 두께, 투명도를 선택할 수 있어야 합니다.

원 안에 예시가 있는 이미지를 보세요.

감사합니다

데이터 탐색 및 시각화Re: 그래프

범위 오류 막대를 사용해 보세요.

또는 간격 막대 차트를 추가하고 "중간" 값을 비활성화할 수 있습니다(여기에는 추가 계산/열이 필요할 수 있음)

그리고 물론 그래픽 스크립트를 사용하는 스크립팅 옵션이 있는데 이는 더 복잡합니다.

Re: 그래프

스크립트 옵션에 대한 가능한 예는 다음과 같습니다.

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Formula Column(Operation(Category("Aggregate"), "Minimum"), Columns(:height), Group By(:age));
dt << New Formula Column(Operation(Category("Aggregate"), "Maximum"), Columns(:height), Group By(:age));

gb = dt << Graph Builder(
	Size(525, 448),
	Show Control Panel(0),
	Variables(
		X(:age),
		Y(:height),
		Y(:"Maximum[height][age]"n, Position(1)),
		Y(:"Minimum[height][age]"n, Position(1))
	),
	Elements(Points(X, Y(1), Y(2), Y(3), Legend(3), Summary Statistic("Mean")))
);



segs = Report(gb)[FrameBox(1)] << Find Segs();
ys = [];
xs = {};
For Each({seg}, segs, 
	If(seg << Class Name == "MarkerSeg", 
		ys = ys |/ (seg << get y values)`;
		Insert Into(xs, seg << get x values);
	)
);

For Each({{ymin, ymax, x}}, Across(V Min(ys), V Max(ys), xs[1]), 
	Eval(EvalExpr(
		Report(gb)[FrameBox(1)] << Add Graphics Script(
			"Back",
			Pen Color("Purple");
			Pen Size(20);
			Transparency(0.2);
			V Line(Expr(x), Expr(ymin), Expr(ymax));
		);
	));
);

Write();

이 "간단한" 예는 필터와 함께 작동하지 않습니다.

Re: 그래프

그리고 범례에서 색상과 투명도를 제어할 수 있고 그리기 표현식에서 너비를 제어할 수 있는 Marker Draw Expr이 있습니다.

더 보기...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt << New Formula Column(Operation(Category("Aggregate"), "Minimum"), Columns(:height), Group By(:age));
dt << New Formula Column(Operation(Category("Aggregate"), "Maximum"), Columns(:height), Group By(:age));

gb = dt << Graph Builder(
	Size(746, 818),
	Show Control Panel(0),
	Variables(
		X(:age),
		Y(:height),
		Y(:"Maximum[height][age]"n, Position(1)),
		Y(:"Minimum[height][age]"n, Position(1))
	),
	Elements(
		Points(X, Y(1), Y(2), Y(3), Legend(3), Summary Statistic("Mean")),
		Points(X, Y(1), Legend(4), Summary Statistic("Mean"))
	),
	Local Data Filter(Add Filter(columns(:age), Display(:age, N Items(6)))),
	SendToReport(
		Dispatch({}, "400", ScaleBox,
			{Legend Model(
				4,
				Properties(
					0,
					{Line Color(35), Transparency(0.2)},
					Item ID("Mean(height)", 1)
				)
			)}
		)
	)
);

frame = Report(gb)[FrameBox(1)];
seg = (frame << FindSeg(Marker Seg(4)));
seg << Set Marker Draw Expr(
	Function({this seg, this row, x, y, size, row state},
		size = 0.1;
		Rect(
			x - size,
			:"Maximum[height][age]"n[this row], 
			x + size,
			:"Minimum[height][age]"n[this row],
			1
		);
	);
);