892420_zh-CN

liliconcom

是否有首选项设置可以隐藏旧版控制图警告？

大家好，

JMP v18 用户

我很好奇是否有人找到了 JMP 首选项设置来隐藏或删除 JMP 18 中出现的旧版 CC 警告。

我们有一些 JMP 用户正在运行 JSL 代码为客户构建某些类型的报表，他们想要隐藏此警告，但又不想手动隐藏。我在这里找到了一个可以隐藏警告的脚本解决方案，发布于 2024 年 9 月。我只是想知道，自从那篇文章最初是通过“JMP”>“首选项”菜单创建的（用户对脚本编写经验不多）以来，是否有人找到了解决方案。

谢谢！，

DS

自动化和脚本大规模定制质量与工艺工程分享和交流结果回复：是否有首选项设置可以隐藏旧版控制图警告？

别让我开始。我不知道有什么偏好，而且我仍然不明白他们为什么要移除传统的控制图平台。

回复：是否有首选项设置可以隐藏旧版控制图警告？

@SDF1

编辑：哎呀，没有读到关于不想要脚本解决方案的部分！

EDIT2：在 EA19 中，有一种方法可以关闭警报。下面的脚本仍然可以运行，并且有一个警报开关：

我认为没有办法隐藏“首选项”中的警报，但警告只是控制图报告中的文本框。

以下是删除它们的一种方法：

names default to here(1);
dt = open( "$SAMPLE_DATA\Tablet Measurements.jmp");
cc = dt << Control Chart(
	Group Size( 1 ),
	KSigma( 3 ),
	Chart Col( :Weight, Individual Measurement, Moving Range ),
);
<BR />// find the text boxes
textboxes = report( cc ) << xpath( "//TextBox" );
<BR />// delete the text box if it contains "Legacy"<BR />for each( {box}, textboxes,
	if( contains( box << get text, "Legacy" ), box << delete )
)

回复：是否有首选项设置可以隐藏旧版控制图警告？

这可能是全局窗口处理程序可以与插件/工具栏项一起使用来创建处理程序（或使用启动脚本）的一种情况。

Set Global Window Handler(
	Function({window},
		Local({tebs},
			tebs = window << XPath("//TextBox[text()='Legacy Control Charts are being removed in JMP 19. Please use Control Chart Builder from the Quality and Process menu instead.']");
			If(N Items(tebs) > 0,
				tebs << Visibility("Collapse");
				Write("\!N", N Items(tebs), " legacy text boxes hidden from ", window << Get Window Title);
				wait(0);
			);		
		);
	);
);

运行该脚本，然后创建遗留控制图以查看其工作原理

Names Default To Here(1);

dt = Open("$SAMPLE_DATA\Tablet Measurements.jmp");
cc = dt << Control Chart(
	Group Size(1),
	KSigma(3),
	Chart Col(:Weight, Individual Measurement, Moving Range)
);

Write();

您也可以从窗口处理程序中获取函数并将其用作用户可以使用的函数。

Names Default To Here(1);

hide_legacy_cc_text = Function({window}, {Default Local},
	tebs = window << XPath("//TextBox[text()='Legacy Control Charts are being removed in JMP 19. Please use Control Chart Builder from the Quality and Process menu instead.']");
	If(N Items(tebs) > 0,
		tebs << Visibility("Collapse");
		Write("\!N", N Items(tebs), " legacy text boxes hidden from ", window << Get Window Title);
		wait(0);
	);		
);


dt = Open("$SAMPLE_DATA\Tablet Measurements.jmp");
cc = dt << Control Chart(
	Group Size(1),
	KSigma(3),
	Chart Col(:Weight, Individual Measurement, Moving Range)
);

hide_legacy_cc_text(cc);

回复：是否有首选项设置可以隐藏旧版控制图警告？

Jarmo，太棒了！现在，如果我们能用 JMP 19 重新添加这个平台就好了……