Come faccio a far sì che il Gruppo X visualizzi tutti gli elementi o solo alcuni?Come faccio a far sì che il Gruppo X visualizzi tutti gli elementi o solo alcuni?
Come mostrato nel JSL qui sotto, usando Where si può far sì che il Gruppo X visualizzi solo elementi specifici. Tuttavia, non è possibile alternare la visualizzazione di tutti gli elementi e quella di elementi parziali. Come si potrebbe modificare questa impostazione? Forse è necessario usare add variable(), ma non riesco a trovare come usare add where.
Names Default To Here( 1 );
selection = 1;
New Window( "Example",
cb = Combo Box( {"Only age 13 and 16", "All age"}, selection = (cb << Get()) ),
Button Box( "Plot",
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
gb = dt << Graph Builder(
Size( 528, 500 ),
Show Control Panel( 0 ),
Variables( X( :sex ), X( :age, Position( 1 ) ), Y( :height ), Group X( :age ) ),
Elements( Points( X( 1 ), X( 2 ), Y, Legend( 10 ) ) ),
If( selection == 1,
Where( Contains( {13, 16}, :age ) ),
),
);
)
);
Automazione e scriptingR: Come impostare il Gruppo X per visualizzare tutti gli elementi o solo alcuni?Hai diverse opzioni:
- avere due espressioni separate del generatore di grafici
- usa il filtro dati locale (nascosto)
- crea l'espressione del generatore di grafici con Where
- utilizzare un sottoinsieme collegato (che viene filtrato utilizzando le tue condizioni) per il generatore di grafici
Ecco un modo di usare Where
Names Default To Here(1);
selection = 1;
New Window("Example",
cb = Combo Box({"Only age 13 and 16", "All age"}, selection = (cb << Get())),
Button Box("Plot",
dt = Open("$SAMPLE_DATA/Big Class.jmp");
gb_expr = Expr(Graph Builder(
Size(528, 500),
Show Control Panel(0),
Variables(X(:sex), X(:age, Position(1)), Y(:height), Group X(:age)),
Elements(Points(X(1), X(2), Y, Legend(10)))
));
If(selection == 1,
Insert Into(gb_expr, NameExpr(Where(Contains({13, 16}, :age))));
);
gb = Eval(EvalExpr(Send(dt, Expr(gb_expr))));
)
);
