888194_zh-CN

liliconcom

恢复图形生成器标题？

当我更改标题时，在 JSL 中有一个命令

Dispatch( {}, {"graph title"}, TextEditBox, {Set Text( "xx" )} )

已添加。

是否有 JSL 命令可以将 Graph Builder 中的标题恢复为默认值？

自动化和脚本数据探索与可视化回复：恢复图形生成器标题？

我目前的解决方法：

• 获取报告脚本
• 关闭报告
• 从检索到的脚本中删除图形标题的命令
• 执行更改后的代码

回复：恢复图形生成器标题？

不知道是否有办法将 TextEditBox 恢复为默认值，但您可以稍微修改一下解决方法。执行更改后的代码（在 V List Box 或其他程序中执行，这样就不会创建任何可见的内容），从“新”报告中选择标题，更新当前报告，然后关闭新创建的报告。

查看更多...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 454),
	Show Control Panel(0),
	Variables(X(:height), Y(:weight)),
	Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))),
	SendToReport(
		Dispatch({}, "graph title", TextEditBox, {Set Text("ABCD")})
	)
);

reset_gb_title = Function({gb}, {Default Local},
	s = gb << get script;
	titlechange = Extract Expr(s, Dispatch({}, "graph title", TextEditBox, Wild()));
	ngb = Substitute(Name Expr(s), Name Expr(titlechange), Expr(.));

	vlb = V List Box(ngb = ngb);
	default_title = Report(ngb)[TextEditBox(1)] << get text;

	Report(gb)[TextEditBox(1)] << Set Text(default_title);
	vlb << Delete Box();	
	
	Return(1);
);

wait(1); // demo purposes
reset_gb_title(gb);
Write();

回复：恢复图形生成器标题？

不错，好多了——它不会创建新的绘图窗口。