888194_ja-JP

liliconcom

グラフ ビルダーのタイトルを元に戻しますか?

タイトルを変更すると、JSLではコマンド

Dispatch( {}, {"graph title"}, TextEditBox, {Set Text( "xx" )} )

が追加されます。

グラフ ビルダーのタイトルをデフォルト値に戻す JSL コマンドはありますか?

自動化とスクリプトデータの探索と可視化Re: グラフビルダーのタイトルを元に戻しますか?

現在の回避策:

• レポートの原稿を入手する
• レポートを閉じる
• 取得したスクリプトからグラフタイトルのコマンドを削除します
• 変更されたコードを実行する

Re: グラフビルダーのタイトルを元に戻しますか?

TextEditBoxをデフォルト値に戻す方法があるかどうかは分かりませんが、回避策を少し変更することは可能です。変更したコードを実行した後（Vリストボックスなど、何も表示されないように内部で実行してください）、新しいレポートからタイトルを選択し、現在のレポートを更新してから、新しく作成したレポートを閉じてください。

もっと見る...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 454),
	Show Control Panel(0),
	Variables(X(:height), Y(:weight)),
	Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))),
	SendToReport(
		Dispatch({}, "graph title", TextEditBox, {Set Text("ABCD")})
	)
);

reset_gb_title = Function({gb}, {Default Local},
	s = gb << get script;
	titlechange = Extract Expr(s, Dispatch({}, "graph title", TextEditBox, Wild()));
	ngb = Substitute(Name Expr(s), Name Expr(titlechange), Expr(.));

	vlb = V List Box(ngb = ngb);
	default_title = Report(ngb)[TextEditBox(1)] << get text;

	Report(gb)[TextEditBox(1)] << Set Text(default_title);
	vlb << Delete Box();	
	
	Return(1);
);

wait(1); // demo purposes
reset_gb_title(gb);
Write();

Re: グラフビルダーのタイトルを元に戻しますか?

いいですね、ずっといいです - 新しいプロット ウィンドウを作成しません。