888194_fr-FR

liliconcom

Rétablir le titre du générateur de graphiques ?

Lorsque je change le titre, en JSL une commande

Dispatch( {}, {"graph title"}, TextEditBox, {Set Text( "xx" )} )

est ajouté.

Existe-t-il une commande JSL pour rétablir le titre dans Graph Builder à la valeur par défaut ?

Automatisation et scriptsExploration et visualisation des donnéesRe : Rétablir le titre du générateur de graphiques ?

ma solution de contournement actuelle :

• obtenir le script du rapport
• fermer le rapport
• supprimer la commande pour le titre du graphique du script récupéré
• exécuter le code modifié

Re : Rétablir le titre du générateur de graphiques ?

Je ne sais pas s'il existe un moyen de rétablir la valeur par défaut de TextEditBox, mais vous pouvez légèrement modifier votre solution. Après avoir exécuté le code modifié (dans une liste déroulante V ou autre, afin qu'il ne crée rien de visible), sélectionnez le titre du « nouveau » rapport, mettez à jour le titre actuel, puis fermez le nouveau.

Voir plus...

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");

gb = dt << Graph Builder(
	Size(528, 454),
	Show Control Panel(0),
	Variables(X(:height), Y(:weight)),
	Elements(Points(X, Y, Legend(1)), Smoother(X, Y, Legend(2))),
	SendToReport(
		Dispatch({}, "graph title", TextEditBox, {Set Text("ABCD")})
	)
);

reset_gb_title = Function({gb}, {Default Local},
	s = gb << get script;
	titlechange = Extract Expr(s, Dispatch({}, "graph title", TextEditBox, Wild()));
	ngb = Substitute(Name Expr(s), Name Expr(titlechange), Expr(.));

	vlb = V List Box(ngb = ngb);
	default_title = Report(ngb)[TextEditBox(1)] << get text;

	Report(gb)[TextEditBox(1)] << Set Text(default_title);
	vlb << Delete Box();	
	
	Return(1);
);

wait(1); // demo purposes
reset_gb_title(gb);
Write();

Re : Rétablir le titre du générateur de graphiques ?

Bien, bien mieux - cela ne crée pas de nouvelle fenêtre de tracé.