887979_ko-KR

liliconcom

다른 테이블의 두 값 사이에 날짜/시간이 있는 데이터 테이블의 모든 행 선택

안녕,

HVAC와 Events라는 두 개의 데이터 테이블이 있습니다. Events 테이블의 시작 시간과 종료 시간을 기준으로 HVAC 테이블의 날짜/시간을 일치시키고, HVAC 테이블에서 일치하는 행에 1을 표시하고 싶습니다.

"일치" 열에 내용이 채워지지 않지만 실행되는 스크립트가 있는데 그 이유가 무엇인지 잘 모르겠습니다.

Names Default to Here (1);
Clear Symbols();
// Reference both tables
timeEvents = DataTable("Events");
timeHVAC = DataTable("HVAC");

// Get column references
startCol = timeEvents:Round_when_started;
endCol = timeEvents:Round_when_ended;
timeHVACCol = timeHVAC:Round_date;
matchedCol = timeHVAC:Matched;
Batch Interactive( 1 );

// Loop through timeEvents and tag matches
For(i = 1, i <= N Rows(timeEvents), i++,
    startTime = startCol[i];
    endTime = endCol[i];

    // Loop through HVAC and tag matching rows
    For(j = 1, j <= N Rows(timeHVAC), j++,
        eventTime = timeHVACCol[j];
        If(eventTime >= startTime & eventTime <= endTime,
            matchedCol[j] = 1;
        );
    );
);
Batch Interactive( 0 );

// Notify user
New Window("Script Completed",
    Text Box("Lucy, I'm home!")
);

자동화 및 스크립팅Re: 다른 테이블의 두 값 사이에 날짜/시간이 있는 데이터 테이블의 모든 행 선택

내가 이걸 처리할 방법은 다음과 같습니다.

Names Default To Here( 1 );
Clear Symbols();
// Reference both tables
timeEvents = Data Table( "Events" );
timeHVAC = Data Table( "HVAC" );

For( i = 1, i <= N Rows( timeEvents ), i++,
	Try(
		timeHVAC:Matched[timeHVAC << get rows where(
			timeHVAC:Round_date >= timeEvents:Round_when_started[i] & timeHVAC
			:Round_date <= timeEvents:Round_when_ended[i]
		)] = 1
	)
);

Re: 다른 테이블의 두 값 사이에 날짜/시간이 있는 데이터 테이블의 모든 행 선택

데이터가 이렇게 표시되고(시간 단위도 마찬가지) 스크립트에 정의된 대로 일치 항목이 정의되어 있다면 이중 조인/업데이트를 통해 이 작업을 수행할 수 있습니다. 이벤트 테이블에 일치 열을 추가하세요.

그런 다음 먼저 Round_date와 Round_when_started를 사용하여 조인합니다.

두 번째 조인에서는 Round_date와 round_when_ended를 사용합니다.

물론, 짐이 보여준 것과 같은 것을 사용할 수도 있습니다.

Re: 다른 테이블의 두 값 사이에 날짜/시간이 있는 데이터 테이블의 모든 행 선택

고맙습니다, 짐.

작동했습니다!

건배!

Re: 다른 테이블의 두 값 사이에 날짜/시간이 있는 데이터 테이블의 모든 행 선택

안녕하세요, Jarmo님.

죄송합니다. JMP Pro가 아니라 JMP를 사용한다는 것을 게시했어야 했습니다.

더블 조인은 전혀 생각해 본 적이 없는데 쿼리 빌더에서 시도해 볼 수도 있겠습니다.

건배!

Re: 다른 테이블의 두 값 사이에 날짜/시간이 있는 데이터 테이블의 모든 행 선택

제가 한 작업에는 JMP Pro가 필요 없을 것 같습니다. 저는 테이블 > 업데이트(표준 JMP에서 사용 가능해야 합니다)를 두 번 사용했지만, 쿼리 빌더를 사용하여 단일 쿼리로 작업할 수도 있습니다.

계산된 열 하나를 추가했습니다.

더 보기...

SQL 쿼리는

SELECT t1.Round_date, t1."Building pressure", t1."Plant Temp", t1."Zone Humdity", 
	t1."outside air temp", t3.Round_when_ended IS NOT NULL  OR  t2.Round_when_started IS NOT NULL AS Calc1, t3.Round_when_ended IS NOT NULL  OR  t2.Round_when_started IS NOT NULL AS "Calc1 2" 
FROM HVAC  t1 
	LEFT OUTER JOIN Events t3 
		ON  ( t1.Round_date = t3.Round_when_ended )  
	LEFT OUTER JOIN Events t2 
		ON  ( t1.Round_date = t2.Round_when_started );

그리고 JMP의 쿼리 빌더 스크립트는 다음과 같습니다.

New SQL Query(
	Version(130),
	Connection("JMP"),
	JMP Tables(["Events" => "\C:\Users\jarmo\Downloads\Events.jmp", "HVAC" => "\C:\Users\jarmo\Downloads\HVAC.jmp"]),
	QueryName("SQLQuery1"),
	Select(
		Column("Round_date", "t1", Numeric Format("m/d/y h:m:s", "0", "NO", "")),
		Column("Building pressure", "t1", Numeric Format("Fixed Dec", "0", "NO", "")),
		Column("Plant Temp", "t1", Numeric Format("Fixed Dec", "0", "NO", "")),
		Column("Zone Humdity", "t1", Numeric Format("Fixed Dec", "0", "NO", "")),
		Column("outside air temp", "t1", Numeric Format("Fixed Dec", "0", "NO", "")),
		ExprLookup("Calc1", JMP Name("Calc1"))
	),
	From(
		Table("HVAC", Alias("t1")),
		Table(
			"Events",
			Alias("t3"),
			Join(
				Type(Left Outer),
				EQ(
					Column("Round_date", "t1", Numeric Format("m/d/y h:m:s", "0", "NO", "")),
					Column("Round_when_ended", "t3", Numeric Format("y/m/d h:m:s", "0", "NO", ""))
				)
			)
		),
		Table(
			"Events",
			Alias("t2"),
			Join(
				Type(Left Outer),
				EQ(
					Column("Round_date", "t1", Numeric Format("m/d/y h:m:s", "0", "NO", "")),
					Column("Round_when_started", "t2", Numeric Format("y/m/d h:m:s", "0", "NO", ""))
				)
			)
		),
		Expression("t3.Round_when_ended IS NOT NULL  OR  t2.Round_when_started IS NOT NULL", Alias("Calc1"))
	),
	Where(Custom("", UI(Custom(Base("Continuous")))))
) << Run;