883796_es-ES

liliconcom

Administrador de columnas > Script para convertir en tabla de datos

Intenté hacer clic manualmente en elAdministrador de columnasy elConvertir en tabla de datosOpción, y el script se guardó así. Al duplicarlo y ejecutarlo, se encontró el error adjunto. ¿Cómo puedo generar una tabla de datos desde el Administrador de Columnas usando un script JSL?

Names Default To Here( 1 );
Assign( rpt );
Wait( 0 );
rpt["Columns Manager", Table Box( 1 )] << Make Into Data Table;
rpt << Close Window;

Automatización y scriptingRe: Administrador de columnas > Script para convertir en tabla de datos

Aquí está el script que produje que crea una tabla de datos desde el Administrador de columnas

Names Default To Here( 1 );
dt=current data table();
main menu("columns manager");
rpt = window(dt << get name || " - Columns Manager");
Wait( 0 );
rpt["Columns Manager", Table Box( 1 )] << Make Combined Data Table;
rpt << Close Window;

Re: Administrador de columnas > Script para convertir en tabla de datos

El administrador de columnas parece devolver una referencia un poco extraña, y hay que hacer algo más para extraer la tabla de datos ( @julian, no estoy seguro de si esto está corregido en JMP19). Aquí hay una opción más.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
cm = dt << Columns Manager(
	Hide Hidden Columns(0),
	Hide Excluded Columns(0),
	Include Extended Statistics(1),
	Force calculations for all numeric columns(1),
	Force calculations for all categorical columns(1)
);
wait(0);
(cm << top parent)[TableBox(1)] << Make into Data Table();

No estoy seguro de si wait(0) siempre será suficiente para el administrador de columnas, ya que creo que puede calcular dinámicamente las estadísticas. Y si tienes grupos de columnas, tendrás que expandirlos primero.

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Probe.jmp");
dt << Expand All Column Groups;
cm = dt << Columns Manager(
	Hide Hidden Columns(0),
	Hide Excluded Columns(0),
	Include Extended Statistics(1),
	Force calculations for all numeric columns(1),
	Force calculations for all categorical columns(1)
);
wait(0);
(cm << top parent)[TableBox(1)] << Make into Data Table();

¿Has probado si el Diccionario de datos sería suficiente para tu caso de uso?

Re: Administrador de columnas > Script para convertir en tabla de datos

¡Muchas gracias! Funcionó.

Re: Administrador de columnas > Script para convertir en tabla de datos

¡Gracias! Esto también funcionó.