883796_ja-JP

liliconcom

列マネージャ > データテーブルスクリプトの作成

手動でクリックしてみました列マネージャーそしてデータテーブルにするオプションを選択し、スクリプトは次のように保存されました。スクリプトを複製して実行すると、添付のエラーが発生しました。JSLスクリプトを使用して列マネージャーからデータテーブルを生成するにはどうすればよいですか？

Names Default To Here( 1 );
Assign( rpt );
Wait( 0 );
rpt["Columns Manager", Table Box( 1 )] << Make Into Data Table;
rpt << Close Window;

自動化とスクリプトRe: 列マネージャ > データテーブルスクリプトの作成

これは私が作成した、列マネージャからデータテーブルを作成するスクリプトです。

Names Default To Here( 1 );
dt=current data table();
main menu("columns manager");
rpt = window(dt << get name || " - Columns Manager");
Wait( 0 );
rpt["Columns Manager", Table Box( 1 )] << Make Combined Data Table;
rpt << Close Window;

Re: 列マネージャ > データテーブルスクリプトの作成

列マネージャは少し奇妙な参照を返すようで、データテーブルを取得するには少し手間がかかります（ @julianはJMP19でこれが修正されたかどうかは不明です）。もう一つの選択肢をご紹介します。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");
cm = dt << Columns Manager(
	Hide Hidden Columns(0),
	Hide Excluded Columns(0),
	Include Extended Statistics(1),
	Force calculations for all numeric columns(1),
	Force calculations for all categorical columns(1)
);
wait(0);
(cm << top parent)[TableBox(1)] << Make into Data Table();

列マネージャは統計情報を動的に計算できると思うので、wait(0) で常に十分かどうかはわかりません。また、列グループがある場合は、まずそれらを展開する必要があります。

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Probe.jmp");
dt << Expand All Column Groups;
cm = dt << Columns Manager(
	Hide Hidden Columns(0),
	Hide Excluded Columns(0),
	Include Extended Statistics(1),
	Force calculations for all numeric columns(1),
	Force calculations for all categorical columns(1)
);
wait(0);
(cm << top parent)[TableBox(1)] << Make into Data Table();

データ ディクショナリがあなたのユースケースに十分かどうか試しましたか?

Re: 列マネージャ > データテーブルスクリプトの作成

ありがとうございます！うまくいきました。

Re: 列マネージャ > データテーブルスクリプトの作成

ありがとうございます！これもうまくいきました。