882968_zh-TW

liliconcom

圖表匯出

我正在使用本地數據過濾器來更改圖表，但我希望它遍歷每個“切換器”，並將每個切換器列印到 PowerPoint 幻燈片上。 JMP18 可以實現嗎？

數據探索與視覺化回覆：圖表匯出

你可以使用與列切換器類似的思路，但資料過濾器的操作會更加複雜。以下是一個選項

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Size(525, 454),
	Show Control Panel(0),
	Variables(X(:weight), Y(:height), Overlay(:sex)),
	Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
	Local Data Filter(
		Add Filter(columns(:age), Display(:age, N Items(6)))
	)
);

Summarize(dt, items = By(:age));
lbb = (Report(gb) << top parent)["Local Data Filter", ListBoxBox(1)];

pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);

For(i = 1, i <= N Items(items), i++,
	lbb << Clear Selection;
	lbb << Set Selected(i);
	gb << Save Presentation(pptx_loc, Append);
	wait(0);
);

// Web(pptx_loc);

Write();

但你有沒有考慮過用頁面取代本地資料過濾器？這樣更簡單

Names Default To Here(1); 

dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
	Show Control Panel(0),
	Variables(X(:weight), Y(:height), Overlay(:sex), Page(:age)),
	Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11)))
);


pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);

// Web(pptx_loc);

Write();

回覆：圖表匯出

您只需將每個圖表儲存到 JMP 日誌（Ctrl+J）。儲存所有版本的圖表後，打開日誌並匯出到 PowerPoint。