Estoy usando un filtro de datos local para modificar mi gráfico, pero quiero que itere por cada uno de los "switchers" e imprima cada uno en una diapositiva de PowerPoint. ¿Es esto posible en JMP18?
Puedes usar una idea similar a la del selector de columnas, con la excepción de que los filtros de datos son más complejos de manipular. A continuación se muestra una opción.
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(525, 454),
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
Local Data Filter(
Add Filter(columns(:age), Display(:age, N Items(6)))
)
);
Summarize(dt, items = By(:age));
lbb = (Report(gb) << top parent)["Local Data Filter", ListBoxBox(1)];
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
For(i = 1, i <= N Items(items), i++,
lbb << Clear Selection;
lbb << Set Selected(i);
gb << Save Presentation(pptx_loc, Append);
wait(0);
);
// Web(pptx_loc);
Write();
¿Pero has considerado usar la página en lugar del filtro de datos local? Es mucho más sencillo.
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex), Page(:age)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11)))
);
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
// Web(pptx_loc);
Write();
Solo tienes que guardar cada gráfico en el diario JMP (Ctrl>J). Una vez que tengas todas las versiones de los gráficos en el diario, ábrelo y expórtalo a PowerPoint.
