Sto usando un filtro dati locale per modificare il mio grafico, ma voglio che esegua l'iterazione di ognuno degli "switcher" e li stampi su una diapositiva di PowerPoint. È possibile in JMP18?
È possibile utilizzare un'idea simile a quella del cambio di colonna, con l'eccezione che i filtri dati sono più complicati da gestire. Di seguito è riportata un'opzione.
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(525, 454),
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
Local Data Filter(
Add Filter(columns(:age), Display(:age, N Items(6)))
)
);
Summarize(dt, items = By(:age));
lbb = (Report(gb) << top parent)["Local Data Filter", ListBoxBox(1)];
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
For(i = 1, i <= N Items(items), i++,
lbb << Clear Selection;
lbb << Set Selected(i);
gb << Save Presentation(pptx_loc, Append);
wait(0);
);
// Web(pptx_loc);
Write();
Ma hai mai pensato di usare Pagina invece di Filtro Dati Locale? È molto più semplice.
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex), Page(:age)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11)))
);
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
// Web(pptx_loc);
Write();
Tutto quello che devi fare è salvare ogni grafico nel Journal di JMP (ctrl>j). Una volta che tutte le versioni dei grafici sono presenti nel journal, apri il journal ed esportalo in PowerPoint.
