Ich verwende einen lokalen Datenfilter, um mein Diagramm zu ändern, möchte aber, dass es alle „Umschalter“ durchläuft und jeden auf einer PowerPoint-Folie ausgibt. Ist das in JMP18 möglich?
Sie können eine ähnliche Idee wie beim Spaltenumschalter verwenden, mit der Ausnahme, dass die Bearbeitung von Datenfiltern komplizierter ist. Unten ist eine Option
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(525, 454),
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
Local Data Filter(
Add Filter(columns(:age), Display(:age, N Items(6)))
)
);
Summarize(dt, items = By(:age));
lbb = (Report(gb) << top parent)["Local Data Filter", ListBoxBox(1)];
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
For(i = 1, i <= N Items(items), i++,
lbb << Clear Selection;
lbb << Set Selected(i);
gb << Save Presentation(pptx_loc, Append);
wait(0);
);
// Web(pptx_loc);
Write();
Aber haben Sie schon einmal darüber nachgedacht, die Seite anstelle des lokalen Datenfilters zu verwenden? Es ist viel einfacher
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex), Page(:age)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11)))
);
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
// Web(pptx_loc);
Write();
Sie müssen lediglich jedes Diagramm im JMP-Journal speichern (Strg>J). Sobald alle Diagrammversionen im Journal vorhanden sind, öffnen Sie das Journal und exportieren Sie es nach PowerPoint.
