J'utilise un filtre de données local pour modifier mon graphique, mais je souhaite qu'il parcoure chaque « switcher » et imprime chaque élément sur une diapositive PowerPoint. Est-ce possible dans JMP18 ?
Vous pouvez utiliser une idée similaire à celle du sélecteur de colonnes, à la différence que les filtres de données sont plus complexes à manipuler. Voici une option :
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Size(525, 454),
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11))),
Local Data Filter(
Add Filter(columns(:age), Display(:age, N Items(6)))
)
);
Summarize(dt, items = By(:age));
lbb = (Report(gb) << top parent)["Local Data Filter", ListBoxBox(1)];
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
For(i = 1, i <= N Items(items), i++,
lbb << Clear Selection;
lbb << Set Selected(i);
gb << Save Presentation(pptx_loc, Append);
wait(0);
);
// Web(pptx_loc);
Write();
Mais avez-vous envisagé d'utiliser Page plutôt que le filtre de données local ? C'est beaucoup plus simple.
Names Default To Here(1);
dt = open("$SAMPLE_DATA/Big Class.jmp");
gb = dt << Graph Builder(
Show Control Panel(0),
Variables(X(:weight), Y(:height), Overlay(:sex), Page(:age)),
Elements(Points(X, Y, Legend(9)), Line Of Fit(X, Y, Legend(11)))
);
pptx_loc = "$TEMP/powerpoint_test.pptx";
gb << Save Presentation(pptx_loc);
// Web(pptx_loc);
Write();
Il vous suffit d'enregistrer chaque graphique dans le journal JMP (Ctrl>j). Une fois toutes les versions des graphiques dans le journal, ouvrez-le et exportez-le vers PowerPoint.
