882637_ko-KR

liliconcom

부모 테이블에서 열 그룹 복사

부모 테이블에서 요약을 만들고 있습니다. 부모 테이블의 열이 그룹화되어 있는데, 요약 테이블에서도 그룹화를 유지하고 싶습니다. 요약 테이블의 열 이름을 부모 테이블과 맞춰서 변경했는데, 도움이 될까요?

자동화 및 스크립팅Re: 부모 테이블에서 열 그룹 복사

스크립팅 인덱스를 살펴보셨나요?(<< 열 그룹 이름 가져오기, <

Re: 부모 테이블에서 열 그룹 복사

자르모

확인해 보니 head도 tail도 만들 수 없었습니다. 이전 스크립트의 일부를 훔쳐 왔습니다. dt는 부모 테이블을 참조하고 dtbest는 요약 테이블을 참조합니다. 잘 작동하는 것 같습니다.

Grps = dt << Get Column Groups Names;

For( j = 1, j <= N Items( Grps ), j++,
colrefs={};
colrefs = dt << get column group(Grps[j]);

Group = dtBest << Group Columns(colrefs);
dtBest << rename column group( Group, Grps[j] );
	
);

Re: 부모 테이블에서 열 그룹 복사

For Each({groupname}, dt << Get Column Groups Names,
	cols = dt << Get Column Group(groupname);
	dt_new << Group Columns(groupname, cols);
);

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Cities.jmp");

dt << group columns("xy", {:X, :y}); // for demo purposes
dt << group columns("pollutants", :Ozone :: :Lead); // for demo purposes

dt_summary = dt << Summary(
	Group(:X, :Y, :OZONE, :CO, :SO2, :NO, :PM10, :Lead, :city),
	Freq("None"),
	Weight("None"),
	Link to original data table(0),
	output table name(
		"Summary of Cities grouped by X, Y, OZONE, CO, SO2, NO, PM10, Lead, city"
	)
);
dt_summary << Ungroup Columns(); // for demo purposes, they are grouped by default 

For Each({groupname}, dt << Get Column Groups Names,
	cols = dt << Get Column Group(groupname);
	dt_summary << Group Columns(groupname, cols);
);