881471_de-DE

liliconcom

Textanmerkungen im Graph Builder hinzufügen

Hallo,
Gibt es eine Möglichkeit, ein Grafikskript zu schreiben, um jedem Fadenkreuz auf der Waferkarte eine Textanmerkung hinzuzufügen?
Zusätzlich möchte ich zwei Spalten – „Ret“ und „%Fail“ – einfärben, eine Heatmap mit der Spalte „%Fail“ erstellen und die Spalte „Ret“ darüberlegen. Ist das in GB möglich?

LIEBE

Automatisierung und SkriptingDatenexploration und -visualisierungBetreff: Textanmerkung zum Graph Builder hinzufügen

Wie würdest du in diesem Fall mit zwei Spalten färben? Reticle würde die Hauptfarbe definieren und %Fail den Farbverlauf oder etwas Ähnliches? Hast du schon mal darüber nachgedacht, eine Shape-Map-Datei für diese Art der Analyse zu erstellen?

Sie können Grafikskript verwenden, um die Textanmerkung hinzuzufügen

Names Default To Here(1);

dt = Current Data Table();

gb = dt << Graph Builder(
	Size(979, 588),
	Variables(X(:X), Y(:Y), Overlay(:Ret)),
	Elements(Points(X, Y, Legend(10)), Smoother(X, Y, Legend(11)))
);

Summarize(dt, rets = By(:Ret), mx = Mean(:X), my = Mean(Y));

// Lazy option without evaluation
Report(gb)[FrameBox(1)] << Add Graphics Script(
	For(i = 1, i <= N Items(rets), i++,
		Text Color("Black");
		Text Size(12);
		Pen Color("Black");
		Pen Size(3);
		Text(Boxed, Erased, Center Justified, {mx[i], my[i]}, rets[i]);
	);
);

Betreff: Textanmerkungen zum Graph Builder hinzufügen

Hallo @jthi ,

Ich habe die Shap-Map ausprobiert, aber sie verlangsamt JMP, weil ich 1 Million Zeilen habe.

Ich habe mir überlegt, ob es eine Möglichkeit gibt, den Rahmen um die Fadenkreuze mithilfe eines Grafikskripts zu zeichnen. Ich kann diese Fadenkreuze auf der Waferkarte einrahmen und so die Fadenkreuze unterscheiden. Anschließend kann ich %Fail zur Farbauswahl in der Legende hinzufügen.

Danke,

Betreff: Textanmerkungen zum Graph Builder hinzufügen

Sie können so etwas tun

oder vielleicht mit einer Heatmap

Betreff: Textanmerkung zum Graph Builder hinzufügen

@jthi Das sieht super aus. Kannst du den Code teilen?

Betreff: Textanmerkungen zum Graph Builder hinzufügen

/*""" Reticle outline and names

Author: jthi
Creation Date: 2025-06-25
Creation JMP Version: JMP Pro 18.2.0
	
"""*/

Names Default To Here(1);

dt = Open("$DOWNLOADS/dataTable.jmp");
Summarize(dt, rets = By(:Ret));
aa = Associative Array();

For Each({curret}, rets,
	r = dt << Get Rows Where(:Ret == curret);
	tri = Triangulation(X(dt[r, "X"], dt[r, "Y"]));
	path = tri << Get Hull Path;
	aa[curret] = Associative Array();
	aa[curret]["Path"] = path;
	aa[curret]["X"] = Median(dt[r, "X"]);
	aa[curret]["Y"] = Median(dt[r, "Y"]);
);

gb = dt << Graph Builder(
	Size(937, 542),
	Show Control Panel(0),
	Variables(X(:X), Y(:Y), Color(:"%Fail"n)),
	Elements(Points(X, Y, Legend(10)))
);

For Each({{retname, param}}, aa,
	Eval(EvalExpr(
		Report(gb)[FrameBox(1)] << Add Graphics Script(
			Pen Color("Red"); // outline color for reticles
			Pen Size(3); // reticle outline size
			Path(Expr(param["Path"]), 0); // plots reticle outline
			
			Text Color("Black"); // text color
			Text Size(10); // text size for reticle
			Pen Color("Black"); // text box outline color
			Pen Size(2); // outline size for text box
			Text(Boxed, Erased, Center Justified, {Expr(param["X"]), Expr(param["Y"])}, Expr(retname));
		);
	));
);

Sie könnten die Schleife möglicherweise in das Grafikskript verschieben und keine Schleifenskripte erstellen (ich habe nicht getestet, was besser wäre).

Bearbeiten: Bild der endgültigen Lösung hinzugefügt