881471_fr-FR

liliconcom

Ajouter une annotation de texte sur le générateur de graphiques

Bonjour,
Existe-t-il un moyen d'écrire un script graphique pour ajouter une annotation de texte à chaque réticule sur la carte de la plaquette ?
De plus, je souhaite colorer deux colonnes : « Ret » et « %Fail », créer une carte thermique avec la colonne « %Fail » et superposer la colonne « Ret ». Est-ce possible en GB ?

AMOUR

Automatisation et scriptsExploration et visualisation des donnéesRe : Ajouter une annotation de texte sur le générateur de graphiques

Comment colorieriez-vous avec deux colonnes dans ce cas ? Le réticule définirait la couleur principale et le pourcentage d'échec le dégradé, ou quelque chose de similaire. Avez-vous envisagé de créer un fichier de mappage de formes pour ce type d'analyse ?

Vous pouvez utiliser un script graphique pour ajouter l'annotation de texte

Names Default To Here(1);

dt = Current Data Table();

gb = dt << Graph Builder(
	Size(979, 588),
	Variables(X(:X), Y(:Y), Overlay(:Ret)),
	Elements(Points(X, Y, Legend(10)), Smoother(X, Y, Legend(11)))
);

Summarize(dt, rets = By(:Ret), mx = Mean(:X), my = Mean(Y));

// Lazy option without evaluation
Report(gb)[FrameBox(1)] << Add Graphics Script(
	For(i = 1, i <= N Items(rets), i++,
		Text Color("Black");
		Text Size(12);
		Pen Color("Black");
		Pen Size(3);
		Text(Boxed, Erased, Center Justified, {mx[i], my[i]}, rets[i]);
	);
);

Re : Ajouter une annotation de texte sur le générateur de graphiques

Salut @jthi ,

J'ai essayé la carte shap, mais elle ralentit JMP car j'ai 1 million de lignes.

Je pensais qu'il y avait un moyen de dessiner la bordure autour des réticules en utilisant un script graphique, je peux border ces réticules sur une carte de plaquette et cela me permettra de distinguer les réticules, puis je peux ajouter %Fail à la sélection de couleur sur la légende

Merci,

Re : Ajouter une annotation de texte sur le générateur de graphiques

Tu peux faire quelque chose comme ça

ou peut-être avec une carte thermique

Re : Ajouter une annotation de texte sur le générateur de graphiques

@jthi Ça a l'air génial. Peux-tu partager le code ?

Re : Ajouter une annotation de texte sur le générateur de graphiques

/*""" Reticle outline and names

Author: jthi
Creation Date: 2025-06-25
Creation JMP Version: JMP Pro 18.2.0
	
"""*/

Names Default To Here(1);

dt = Open("$DOWNLOADS/dataTable.jmp");
Summarize(dt, rets = By(:Ret));
aa = Associative Array();

For Each({curret}, rets,
	r = dt << Get Rows Where(:Ret == curret);
	tri = Triangulation(X(dt[r, "X"], dt[r, "Y"]));
	path = tri << Get Hull Path;
	aa[curret] = Associative Array();
	aa[curret]["Path"] = path;
	aa[curret]["X"] = Median(dt[r, "X"]);
	aa[curret]["Y"] = Median(dt[r, "Y"]);
);

gb = dt << Graph Builder(
	Size(937, 542),
	Show Control Panel(0),
	Variables(X(:X), Y(:Y), Color(:"%Fail"n)),
	Elements(Points(X, Y, Legend(10)))
);

For Each({{retname, param}}, aa,
	Eval(EvalExpr(
		Report(gb)[FrameBox(1)] << Add Graphics Script(
			Pen Color("Red"); // outline color for reticles
			Pen Size(3); // reticle outline size
			Path(Expr(param["Path"]), 0); // plots reticle outline
			
			Text Color("Black"); // text color
			Text Size(10); // text size for reticle
			Pen Color("Black"); // text box outline color
			Pen Size(2); // outline size for text box
			Text(Boxed, Erased, Center Justified, {Expr(param["X"]), Expr(param["Y"])}, Expr(retname));
		);
	));
);

Vous pouvez potentiellement déplacer la boucle à l'intérieur du script graphique et ne pas créer de scripts en boucle (je n'ai pas testé ce qui serait mieux).

Modifier : Ajout d'une image de la solution finale