881321_zh-TW

liliconcom

如何動態改變X軸的垂直線？

我這樣畫圖，然後每分鐘循環一次，要求是X軸的垂直線能根據指定變數的值變化
謝謝專家！

a=26;
dt=Open("$SAMPLE_DATA/Big Class.jmp");
ca="r";New Column(ca);
p1=dt<< Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :height ) ),
	Elements( Line( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 )}
		)
	)
);
While( 1,
a=Random Integer(1, 40);//Column(ca)<
     <FORMULA></FORMULA>

<LINGO-LABS id="lingo-labs-881321" slang="en-US" mode="CREATE"> <LINGO-LABEL>自動化和腳本</LINGO-LABEL> </LINGO-LABS> 回覆：如何動態改變X軸的垂直線？

好的

gb_report = p1 << Report; 
axisbox = gb_report[Axis Box( 1 )]; 

While( 1,
	axisbox << Remove Ref Line( a ); 
	a = Random Integer( 1, 40 ); 
	axisbox << Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 ); 
	Wait( 2 ); 
);

回覆：如何動態改變X軸的垂直線？

看來要遇到像 wrap 這樣的重疊並不是那麼簡單

回覆：如何動態改變X軸的垂直線？

使用帶有“全域”變數的圖形腳本

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:height)),
	Elements(Line(X, Y, Legend(5)))
);

Report(gb)[FrameBox(1)] << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();

回覆：如何動態改變X軸的垂直線？

至於實際的例子，我還不知道。

圖表與包裝重疊

原先設定的其他效果都消失了，也沒有出現垂直線條。

回覆：如何動態改變X軸的垂直線？

只有一個謝謝！

回覆：如何動態改變X軸的垂直線？

您可能必須將其新增至所有框架框（Wrap/X Group/Y Group 會建立多個）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Transform Column("Row", Formula(Row())),
	Size(525, 496),
	Show Control Panel(0),
	Variables(X(:Row), Y(:height), Wrap(:age)),
	Elements(Line(X, Y, Legend(5)))
);


fbs = Report(gb) << XPath("//FrameBox");
fbs << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();