881321_es-ES

liliconcom

¿Cómo cambiar dinámicamente la línea vertical del eje X?

Dibujo el gráfico así y lo bucleo cada minuto. El requisito es que la línea vertical del eje X pueda modificarse según el valor de la variable especificada.
¡Gracias expertos!

a=26;
dt=Open("$SAMPLE_DATA/Big Class.jmp");
ca="r";New Column(ca);
p1=dt<< Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :height ) ),
	Elements( Line( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 )}
		)
	)
);
While( 1,
a=Random Integer(1, 40);//Column(ca)<
     <FORMULA></FORMULA>

<LINGO-LABS id="lingo-labs-881321" slang="en-US" mode="CREATE"> <LINGO-LABEL>Automatización y scripting</LINGO-LABEL> </LINGO-LABS> Pregunta: ¿Cómo cambiar dinámicamente la línea vertical del eje X?

DE ACUERDO

gb_report = p1 << Report; 
axisbox = gb_report[Axis Box( 1 )]; 

While( 1,
	axisbox << Remove Ref Line( a ); 
	a = Random Integer( 1, 40 ); 
	axisbox << Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 ); 
	Wait( 2 ); 
);

Pregunta: ¿Cómo cambiar dinámicamente la línea vertical del eje X?

Parece que encontrarse con una superposición como una envoltura no es tan simple.

Re: ¿Cómo cambiar dinámicamente la línea vertical del eje X?

Utilice Graphic Script con variable "global"

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:height)),
	Elements(Line(X, Y, Legend(5)))
);

Report(gb)[FrameBox(1)] << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();

Re: ¿Cómo cambiar dinámicamente la línea vertical del eje X?

En cuanto a ejemplos prácticos, todavía no lo sé.

El gráfico se superpuso con el envoltorio

Los demás efectos originalmente previstos han desaparecido y tampoco han aparecido líneas verticales.

Re: ¿Cómo cambiar dinámicamente la línea vertical del eje X?

¡Solo una gracias!

Re: ¿Cómo cambiar dinámicamente la línea vertical del eje X?

Es posible que tengas que agregarlo a todos los cuadros de marco (Wrap / X Group / Y Group crean varios)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Transform Column("Row", Formula(Row())),
	Size(525, 496),
	Show Control Panel(0),
	Variables(X(:Row), Y(:height), Wrap(:age)),
	Elements(Line(X, Y, Legend(5)))
);


fbs = Report(gb) << XPath("//FrameBox");
fbs << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();