881321_ko-KR

liliconcom

X축의 수직선을 동적으로 변경하는 방법은 무엇입니까?

그래프를 이렇게 그린 다음, 1분마다 한 번씩 반복합니다. 필요한 조건은 X축의 수직선이 지정된 변수 값에 따라 변경될 수 있어야 한다는 것입니다.
전문가 여러분, 감사합니다!

a=26;
dt=Open("$SAMPLE_DATA/Big Class.jmp");
ca="r";New Column(ca);
p1=dt<< Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :height ) ),
	Elements( Line( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 )}
		)
	)
);
While( 1,
a=Random Integer(1, 40);//Column(ca)<
     <FORMULA></FORMULA>

<LINGO-LABS id="lingo-labs-881321" slang="en-US" mode="CREATE"> <LINGO-LABEL>자동화 및 스크립팅</LINGO-LABEL> </LINGO-LABS> 답변: X축의 수직선을 동적으로 변경하는 방법은 무엇입니까?

좋아요

gb_report = p1 << Report; 
axisbox = gb_report[Axis Box( 1 )]; 

While( 1,
	axisbox << Remove Ref Line( a ); 
	a = Random Integer( 1, 40 ); 
	axisbox << Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 ); 
	Wait( 2 ); 
);

답변: X축의 수직선을 동적으로 변경하는 방법은 무엇입니까?

랩과 같은 오버랩을 만나는 것은 그렇게 간단하지 않은 것 같습니다.

Re: X축의 수직선을 동적으로 변경하는 방법은 무엇입니까?

"전역" 변수와 함께 그래픽 스크립트 사용

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:height)),
	Elements(Line(X, Y, Legend(5)))
);

Report(gb)[FrameBox(1)] << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();

Re: X축의 수직선을 동적으로 변경하는 방법은 무엇입니까?

실제적인 사례에 관해서는 아직 잘 모르겠습니다.

그래프가 랩과 겹쳤습니다.

원래 설정된 다른 효과는 사라졌고 수직선도 나타나지 않았습니다.

Re: X축의 수직선을 동적으로 변경하는 방법은 무엇입니까?

하나만 고맙습니다!

Re: X축의 수직선을 동적으로 변경하는 방법은 무엇입니까?

모든 프레임 상자에 추가해야 할 수도 있습니다(Wrap/X 그룹/Y 그룹은 여러 개를 생성합니다)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Transform Column("Row", Formula(Row())),
	Size(525, 496),
	Show Control Panel(0),
	Variables(X(:Row), Y(:height), Wrap(:age)),
	Elements(Line(X, Y, Legend(5)))
);


fbs = Report(gb) << XPath("//FrameBox");
fbs << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();