881321_ja-JP

liliconcom

X 軸の垂直線を動的に変更するにはどうすればよいですか?

このようにグラフを描画し、1分ごとにループします。要件は、指定された変数の値に応じてX軸の縦線を変更できることです。
専門家の皆様、ありがとうございます!

a=26;
dt=Open("$SAMPLE_DATA/Big Class.jmp");
ca="r";New Column(ca);
p1=dt<< Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :height ) ),
	Elements( Line( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 )}
		)
	)
);
While( 1,
a=Random Integer(1, 40);//Column(ca)<
     <FORMULA></FORMULA>

<LINGO-LABS id="lingo-labs-881321" slang="en-US" mode="CREATE"> <LINGO-LABEL>自動化とスクリプト</LINGO-LABEL> </LINGO-LABS> 回答： X 軸の垂直線を動的に変更するにはどうすればよいですか?

わかりました

gb_report = p1 << Report; 
axisbox = gb_report[Axis Box( 1 )]; 

While( 1,
	axisbox << Remove Ref Line( a ); 
	a = Random Integer( 1, 40 ); 
	axisbox << Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 ); 
	Wait( 2 ); 
);

回答： X 軸の垂直線を動的に変更するにはどうすればよいですか?

ラップのような重なりに遭遇するのはそれほど単純ではないようです

Re: X軸の垂直線を動的に変更するにはどうすればいいでしょうか?

「グローバル」変数でグラフィックスクリプトを使用する

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:height)),
	Elements(Line(X, Y, Legend(5)))
);

Report(gb)[FrameBox(1)] << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();

Re: X軸の垂直線を動的に変更するにはどうすればいいでしょうか?

実際の例となると、まだ分かりません。

グラフがラップで重なった

元々設定されていた他のエフェクトも消え、縦線も出なくなりました。

Re: X軸の垂直線を動的に変更するにはどうすればいいでしょうか?

たった1つありがとう！

Re: X軸の垂直線を動的に変更するにはどうすればいいでしょうか?

すべてのフレームボックスに追加する必要があるかもしれません（ラップ/Xグループ/Yグループは複数作成します）

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Transform Column("Row", Formula(Row())),
	Size(525, 496),
	Show Control Panel(0),
	Variables(X(:Row), Y(:height), Wrap(:age)),
	Elements(Line(X, Y, Legend(5)))
);


fbs = Report(gb) << XPath("//FrameBox");
fbs << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();