881321_de-DE

liliconcom

Wie kann die vertikale Linie der X-Achse dynamisch geändert werden?

Ich zeichne das Diagramm so und führe es dann einmal pro Minute aus. Voraussetzung ist, dass die vertikale Linie der X-Achse entsprechend dem Wert der angegebenen Variable geändert werden kann.
Danke, Experten!

a=26;
dt=Open("$SAMPLE_DATA/Big Class.jmp");
ca="r";New Column(ca);
p1=dt<< Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :height ) ),
	Elements( Line( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 )}
		)
	)
);
While( 1,
a=Random Integer(1, 40);//Column(ca)<
     <FORMULA></FORMULA>

<LINGO-LABS id="lingo-labs-881321" slang="en-US" mode="CREATE"> <LINGO-LABEL>Automatisierung und Skripting</LINGO-LABEL> </LINGO-LABS> Frage: Wie kann ich die vertikale Linie der X-Achse dynamisch ändern?

OK

gb_report = p1 << Report; 
axisbox = gb_report[Axis Box( 1 )]; 

While( 1,
	axisbox << Remove Ref Line( a ); 
	a = Random Integer( 1, 40 ); 
	axisbox << Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 ); 
	Wait( 2 ); 
);

Frage: Wie kann ich die vertikale Linie der X-Achse dynamisch ändern?

Es scheint, dass die Begegnung mit einer Überlappung wie Wrap nicht so einfach ist

Betreff: Wie kann ich die vertikale Linie der X-Achse dynamisch ändern?

Verwenden Sie Grafikskript mit „globaler“ Variable

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:height)),
	Elements(Line(X, Y, Legend(5)))
);

Report(gb)[FrameBox(1)] << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();

Betreff: Wie kann ich die vertikale Linie der X-Achse dynamisch ändern?

Was praktische Beispiele angeht, weiß ich es noch nicht.

Der Graph überlappt sich mit Wrap

Die anderen ursprünglich eingestellten Effekte sind verschwunden und es sind auch keine vertikalen Linien erschienen.

Betreff: Wie kann ich die vertikale Linie der X-Achse dynamisch ändern?

nur ein Dankeschön!

Betreff: Wie kann ich die vertikale Linie der X-Achse dynamisch ändern?

Möglicherweise müssen Sie es zu allen Frameboxen hinzufügen (Wrap / X-Gruppe / Y-Gruppe erstellen mehrere)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Transform Column("Row", Formula(Row())),
	Size(525, 496),
	Show Control Panel(0),
	Variables(X(:Row), Y(:height), Wrap(:age)),
	Elements(Line(X, Y, Legend(5)))
);


fbs = Report(gb) << XPath("//FrameBox");
fbs << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();