881321_fr-FR

liliconcom

Comment modifier dynamiquement la ligne verticale de l'axe X ?

Je dessine le graphique comme ceci, puis je le boucle une fois par minute. La condition est que la ligne verticale de l'axe des abscisses puisse être modifiée en fonction de la valeur de la variable spécifiée.
Merci les experts !

a=26;
dt=Open("$SAMPLE_DATA/Big Class.jmp");
ca="r";New Column(ca);
p1=dt<< Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :height ) ),
	Elements( Line( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 )}
		)
	)
);
While( 1,
a=Random Integer(1, 40);//Column(ca)<
     <FORMULA></FORMULA>

<LINGO-LABS id="lingo-labs-881321" slang="en-US" mode="CREATE"> <LINGO-LABEL>Automatisation et scripts</LINGO-LABEL> </LINGO-LABS> Réponse : Comment modifier dynamiquement la ligne verticale de l'axe X ?

D'ACCORD

gb_report = p1 << Report; 
axisbox = gb_report[Axis Box( 1 )]; 

While( 1,
	axisbox << Remove Ref Line( a ); 
	a = Random Integer( 1, 40 ); 
	axisbox << Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 ); 
	Wait( 2 ); 
);

Réponse : Comment modifier dynamiquement la ligne verticale de l'axe X ?

Il semble que rencontrer un chevauchement comme un wrap ne soit pas si simple

Re : Comment modifier dynamiquement la ligne verticale de l'axe X ?

Utiliser un script graphique avec une variable « globale »

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:height)),
	Elements(Line(X, Y, Legend(5)))
);

Report(gb)[FrameBox(1)] << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();

Re : Comment modifier dynamiquement la ligne verticale de l'axe X ?

En ce qui concerne les exemples pratiques, je ne sais toujours pas.

Le graphique est superposé avec un wrap

Les autres effets initialement définis ont disparu et aucune ligne verticale n'est apparue non plus.

Re : Comment modifier dynamiquement la ligne verticale de l'axe X ?

un seul merci !

Re : Comment modifier dynamiquement la ligne verticale de l'axe X ?

Vous devrez peut-être l'ajouter à toutes les frameboxes (Wrap / X Group / Y Group en créent plusieurs)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Transform Column("Row", Formula(Row())),
	Size(525, 496),
	Show Control Panel(0),
	Variables(X(:Row), Y(:height), Wrap(:age)),
	Elements(Line(X, Y, Legend(5)))
);


fbs = Report(gb) << XPath("//FrameBox");
fbs << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();