881321_en-US

liliconcom

How to dynamically change the vertical line of the X-axis?

I draw the graph like this, and then loop it once every minute. The requirement is that the vertical line of the X-axis can be changed according to the value of the specified variable
Thanks Experts!

a=26;
dt=Open("$SAMPLE_DATA/Big Class.jmp");
ca="r";New Column(ca);
p1=dt<< Graph Builder(
	Variables( X( Transform Column( "Row", Formula( Row() ) ) ), Y( :height ) ),
	Elements( Line( X, Y, Legend( 5 ) ) ),
	SendToReport(
		Dispatch(
			{},
			"Row",
			ScaleBox,
			{Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 )}
		)
	)
);
While( 1,
a=Random Integer(1, 40);//Column(ca)<<FORMULA></FORMULA>

Automation and Scripting回复： How to dynamically change the vertical line of the X-axis?

OK

gb_report = p1 << Report; 
axisbox = gb_report[Axis Box( 1 )]; 

While( 1,
	axisbox << Remove Ref Line( a ); 
	a = Random Integer( 1, 40 ); 
	axisbox << Add Ref Line( a, "Dotted", "Medium Light Red", "", 1 ); 
	Wait( 2 ); 
);

回复： How to dynamically change the vertical line of the X-axis?

It seems that encountering an overlap like wrap is not that simple

Re: How to dynamically change the vertical line of the X-axis?

Use Graphic Script with "global" variable

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Variables(X(Transform Column("Row", Formula(Row()))), Y(:height)),
	Elements(Line(X, Y, Legend(5)))
);

Report(gb)[FrameBox(1)] << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();

Re: How to dynamically change the vertical line of the X-axis?

When it comes to practical examples, I still don't know.

 

The graph overlapped with wrap

The other effects originally set have disappeared and no vertical lines have appeared either.

Re: How to dynamically change the vertical line of the X-axis?

only one Thanks!

Re: How to dynamically change the vertical line of the X-axis?

You might have to add it to all of the frameboxes (Wrap / X Group / Y Group do create multiple)

Names Default To Here(1);

dt = Open("$SAMPLE_DATA/Big Class.jmp");
a = 26;

gb = dt << Graph Builder(
	Transform Column("Row", Formula(Row())),
	Size(525, 496),
	Show Control Panel(0),
	Variables(X(:Row), Y(:height), Wrap(:age)),
	Elements(Line(X, Y, Legend(5)))
);


fbs = Report(gb) << XPath("//FrameBox");
fbs << Add Graphics Script(
	Pen Size(2);
	V Line(a);
);

For(i = 1, i <= 10, i++,
	a = Random Integer(1, 40); // could also use table variable
	Wait(0.5);
	Report(gb) << Inval;
	Report(gb) << Update Window;
);

Write();