878440_zh-CN

liliconcom

使用 JSL 手动选择映射两个不同表中的列

我有两张表，我们分别称之为 dt1 和 dt2

每个表在 dt1 中各有一列，在 dt2 中各有一列。

我需要（更新或创建新表）手动选择将 Column1 的内容映射到 Column2 的内容。由于列实体差异很大，因此无法使用连接或更新功能。

我的目标是创建一个用户界面，允许用户逐行选择两列中的内容匹配。

自动化和脚本回复：使用 JSL 手动选择映射两个不同表中的列

Recode 平台中的“从表格应用映射”选项是否适合您的情况？如果可以，可以将其合并到脚本中。

回复：使用 JSL 手动选择映射两个不同表中的列

你好，Jed_campbell，

很遗憾，不行。这假设存在一个将一列映射到另一列的列表。我实际上正在尝试创建这样一个列表。

因此，为了回答这个问题，我们假设我只有两个表 dt1 和 dt2，每个表只有一列，分别是 column1 和 column2，我想将列 1 的一些内容映射到列 2 的内容。 (我使用“一些内容”是因为两列的行数不同)

回复：使用 JSL 手动选择映射两个不同表中的列

啊，如果我理解正确的话，你应该可以这样做。你可以把前两个表替换成你自己的。

Names Default To Here( 1 );

dt1 = New Table( "Table 1",
	Add Rows( 4 ),
	New Column( "Choice1", Character, "Nominal", Set Values( {"A", "B", "C", "D"} ) )
);

dt2 = New Table( "Table 2",
	Add Rows( 5 ),
	New Column( "Choice2", Character, "Nominal", Set Values( {"L", "M", "N", "O", "P"} ) )
);

dtlookup = New Table( "lookuptable",
	Add Rows( 0 ),
	New Column( "dt1choice", Character, "Nominal" ),
	New Column( "dt2choice", Character, "Nominal" )
);
lst1 = Associative Array( dt1:Choice1 ) << get keys;
lst2 = Associative Array( dt2:Choice2 ) << get keys;



nw = New Window( "Chooser",
	H List Box(
		lb1 = List Box( lst1, max selected( 1 ) ),
		lb2 = List Box( lst2, max selected( 1 ) ), 
		
	),
	Button Box( "Make Match",
		dtlookup << add rows(
			{dt1choice = (lb1 << get selected)[1], dt2choice = (lb2 << get selected)[1]}
		)
	)
);

回复：使用 JSL 手动选择映射两个不同表中的列

您好，Jed_Campbell，理论上应该可以运行，但是当我尝试在已打开的表 dt1（包含列 Choice1）和 dt2（包含列 Choice2）上运行此代码时，出现了以下错误。我使用的是 JMP17。

范围数据表访问需要访问或评估“dt1：Choice1”中的数据表列或变量，dt1：Choice1 / *###*/

回复：使用 JSL 手动选择映射两个不同表中的列

我解决了这个问题。非常感谢你的帮助。现在可以正常工作了。

回复：使用 JSL 手动选择映射两个不同表中的列

这是快速拼凑的 UI，略微遵循 JMP 的表连接/更新平台

查看更多...

/*""" Map two columns together

Author: jthi
Creation Date: 2025-06-05
Creation JMP Version: JMP Pro 18.2.0
	
"""*/


Names Default To Here(1);

dt1 = New Table("Untitled", New Column("Column 1", Character, "Nominal", Set Values({"A", "B", "C"})));
dt2 = New Table("Untitled", New Column("Column 2", Character, "Nominal", Set Values({"E", "F", "G", "H"})));


nw = New Window("Matcher",
	Lineup Box(N Col(3),
		V List Box(
			Panel Box("From - Table: " || (dt1 << get name || ", Column: " || (Column(dt1, 1) << get name)),
				window:lb_from = List Box(Column(dt1, 1) << get values)
			),
			Panel Box("To - Table: " || (dt2 << get name || ", Column: " || (Column(dt2, 1) << get name)),
				window:lb_to = List Box(Column(dt2, 1) << get values)
			)
		),
		Panel Box("Match",
			H List Box(align("top"),
				Button Box("Match", 
				<< Set Function(function({this},
					from_selections = window:lb_from << get selected;
					to_selections = window:lb_to << get selected;
					pairs = {};
					For Each({{from, to}}, Across(from_selections, to_selections, Count("Shortest")),
						Insert Into(pairs, Eval Insert("^from^=^to^"));
					);
					window:lb_match << Append(pairs);
				))),
				window:lb_match = List Box({}, << Set N Lines(20))
			)
		),
		Panel Box("Actions",
			Lineup Box(N Col(1),
				Button Box("OK", << Set Function(function({this},
					selections = window:lb_match << get items;
					from_values = {};
					to_values = {};
					For Each({selection}, selections,
						{from, to} = Words(selection, "=");
						Insert Into(from_values, from);
						Insert Into(to_values, to);
					);
					dt_result = New Table(Eval Insert("^(dt1 << get name)^ mapped to ^(dt2 << get name)^"),
						New Column(Column(dt1, 1) << get name, Character, Nominal, Values(from_values)),
						New Column(Column(dt2, 1) << get name, Character, Nominal, Values(to_values))
					);
					If(!(window:cb_keepdialog << get),
						this << close window;
					);
				))),
				Button Box("Cancel", << Set Function(function({this}, this << close window))),
				Spacer Box(Size(0, 10)),
				Button Box("Remove",
					window:lb_match << Remove Selected();
				),
				window:cb_keepdialog = Check Box({"Keep Dialog Open"}, << Set All(1))
			)
		)
	)
);

Write();

还有很多可以改进的地方，例如列选择、清理 UI、错误处理……

回复：使用 JSL 手动选择映射两个不同表中的列

你好，Jarmo，非常感谢。这很有帮助。你的代码比较了每个表的前几列。我们可以修改一下吗？让一个表中任意位置的特定列与第二个表中的特定列（无论列号是多少）进行比较。

回复：使用 JSL 手动选择映射两个不同表中的列

这种方式很容易修改。用户会从第一个表中选取一列，然后假设第二个表中存在相同的列吗？还是用户应该能够从两个表中选取一列？

回复：使用 JSL 手动选择映射两个不同表中的列

最好，用户应该能够从两个表中选择列。

多谢。

回复：使用 JSL 手动选择映射两个不同表中的列

我猜想它应该只是两个表中的单列？我今天应该有时间在脚本中添加必要的更新。

回复：使用 JSL 手动选择映射两个不同表中的列

创建这个表格比我预想的要花更长的时间，因为用户还得能选择第二个表格，这会让事情变得非常混乱，因为所有“好看”的显示框在表格变化时都会有反应（比如筛选器列选择器和列列表框……）。而且我晚上的时间比我预想的要少。

我也开始创建更复杂的用户界面，但我意识到这真的没什么意义，因为JMP的Recode平台应该可以做到这一切。我建议你创建一个关于此的愿望清单（我也可以创建一个，我还有一些额外的建议）。

查看更多...