877462_es-ES

liliconcom

¿Cómo puedo organizar los valores únicos obtenidos de una columna en el orden en que aparecen en la columna original?

Al buscar valores únicos en una columna, se suele usar `summarize()`. Sin embargo, los valores generados por `summarize()` están ordenados, y la salida en el siguiente JSL se vería así: {"64", "67", "74",..., "172"}. Me gustaría que la salida se organizara en el orden en que aparecen en la columna, por ejemplo: {"95", "123", "74",...}. ¿Qué modificación debo realizar para obtener este resultado?

Names Default to Here(1);
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
summarize(unique_values=by(weight));
show(unique_values)

Automatización y scriptingRe: ¿Cómo puedo organizar los valores únicos obtenidos de una columna en el orden en que aparecen en la columna original?

Esto debería funcionar.

Names Default To Here( 1 );
dt = Open( "$SAMPLE_DATA/Big Class.jmp" );
dt << Select Duplicate Rows( Match( :weight ) );
dt << Invert Row Selection;
sl = dt << Get Selected Rows;
unique_vals = dt:weight[sl];

Re: ¿Cómo puedo organizar los valores únicos obtenidos de una columna en el orden en que aparecen en la columna original?

Puede establecer la propiedad de la columna Orden de valor como Nivel de orden de fila

Y luego, cuando utilice Tablas=>Resumen, la nueva tabla de datos se mostrará en el orden de filas.

Re: ¿Cómo puedo organizar los valores únicos obtenidos de una columna en el orden en que aparecen en la columna original?

La tabla de resumen con la columna de transformación de fila() es una opción más (y hay muchas más)

Names Default To Here(1);
dt = Open("$SAMPLE_DATA/Big Class.jmp");

dt_summary = dt << Summary(
	Group(:weight),
	Min(Transform Column("Row", Formula(Row()))),
	Freq("None"),
	Weight("None"),
	statistics column name format("column"),
	private
);

dt_summary << Sort(By(:Row), Replace Table, Order(Ascending));
unique = dt_summary[0, 1];
Close(dt_summary, no save);

show(unique);